[PetterAdriano]

Bom to querendo coloca um dialogid para quando o player for transferir aparece no primeiro dialogid o id do player e no segundo o valor da transferencia mais nгo consigo

PHP код:

CMD:transferir(playerid, params[])
{
    if(sscanf(params, "ui", ID, Dinhero)) 
        return SendClientMessage(playerid, -1, "{BEBEBE}Use /transferir [ID] [Quantidade]");
    if(!IsPlayerConnected(ID)) 
        return SendClientMessage(playerid, -1, "{FF0000}[ERRO]: {FFFFFF}ID Invalido");
    if(GetPlayerMoney(playerid) < Dinhero) 
        return SendClientMessage(playerid, -1, "{FF0000}[ERRO]: {FFFFFF}Vocк nгo contйm esse dinhero!");
    GivePlayerMoney(playerid, -Dinhero); 
    GivePlayerMoney(ID, Dinhero);
    format(String, sizeof(String), "{00FF00}[BANCO]: {FFFFFF}Vocк transferiu {00FF00}%d${FFFFFF}, para o jogador {00FF00}%s{FFFFFF}.", Dinhero, Nome(ID));
    SendClientMessage(playerid, -1, String);
    format(String, sizeof(String), "{00FF00}[BANCO]: {FFFFFF}O jogador {00FF00}%s {FFFFFF}transferiu {00FF00}%d${FFFFFF}, para vocк.", Nome(playerid), Dinhero);
    SendClientMessage(ID, -1, String);
    
    return 1;
} 


[PetterAdriano]

alguйm ?

[Gii]

pawn Код:

#define DIALOG_TRANSFERIR_PEGAR_ID 8000
#define DIALOG_TRANSFERIR_PEGAR_QUANTIA 8001

new Transferir_ID[MAX_PLAYERS];

CMD:transferir(playerid) {

    ShowPlayerDialog(playerid, DIALOG_TRANSFERIR_PEGAR_ID, DIALOG_STYLE_INPUT, "Tranfкrencia", "No campo abaixo digite o ID do jogador que receberб determinada quantia!", "Prуximo", "Fechar");
    return 1;
}

public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[]) {

    if ( dialogid == DIALOG_TRANSFERIR_PEGAR_ID ) {

        if ( response ) {

            Transferir_ID[playerid] = strval(inputtext);

            if ( !IsPlayerConnected(Transferir_ID[playerid]) ) {

                SendClientMessage(playerid, -1, "Jogador offline, por favor informe outro ID!");
                ShowPlayerDialog(playerid, DIALOG_TRANSFERIR_PEGAR_ID, DIALOG_STYLE_INPUT, "Tranfкrencia", "No campo abaixo digite o ID do jogador que receberб determinada quantia!\n", "Prуximo", "Fechar");
            }
            else {

                new str[128];

                format (str, 128, "No campo abaixo digite a quantia que vocк deseja transferir para %s (ID:%d)\nCaso este nгo seja o jogador desejado clique em voltar!", Nome(Transferir_ID[playerid]), Transferir_ID[playerid] );
                ShowPlayerDialog(playerid, DIALOG_TRANSFERIR_PEGAR_QUANTIA, DIALOG_STYLE_INPUT, "Tranferкncia", str, "Prуximo", "Voltar");
            }
            return 1;
        }
    }

    if ( dialogid == DIALOG_TRANSFERIR_PEGAR_QUANTIA ) {

        if ( response ) {

            new Quantia = strval(inputtext), str[128];

            if ( Quantia <= 0 ) {

                SendClientMessage(playerid, -1, "Quantia invбlida!");
                format (str, 128, "No campo abaixo digite a quantia que vocк deseja transferir para %s (ID:%d)\nCaso este nгo seja o jogador desejado clique em voltar!", Nome(Transferir_ID[playerid]), Transferir_ID[playerid] );
                ShowPlayerDialog(playerid, DIALOG_TRANSFERIR_PEGAR_QUANTIA, DIALOG_STYLE_INPUT, "Tranferкncia", str, "Prуximo", "Voltar");
                return 1;
            }

            if (Quantia > GetPlayerMoney(playerid) ) {

                SendClientMessage(playerid, -1, "Vocк nгo tem tudo isso!")
                format (str, 128, "No campo abaixo digite a quantia que vocк deseja transferir para %s (ID:%d)\nCaso este nгo seja o jogador desejado clique em voltar!", Nome(Transferir_ID[playerid]), Transferir_ID[playerid] );
                ShowPlayerDialog(playerid, DIALOG_TRANSFERIR_PEGAR_QUANTIA, DIALOG_STYLE_INPUT, "Tranferкncia", str, "Prуximo", "Voltar");
                return 1;
            }

            GivePlayerMoney(playerid, -Quantia);
            GivePlayerMoney(Transferir_ID[playerid], Quantia);
            format(String, sizeof(String), "{00FF00}[BANCO]: {FFFFFF}Vocк transferiu {00FF00}%d${FFFFFF}, para o jogador {00FF00}%s{FFFFFF}.", Quantia, Nome(Transferir_ID[playerid]));
            SendClientMessage(playerid, -1, String);
            format(String, sizeof(String), "{00FF00}[BANCO]: {FFFFFF}O jogador {00FF00}%s {FFFFFF}transferiu {00FF00}%d${FFFFFF}, para vocк.", Nome(playerid), Quantia);
            SendClientMessage(Transferir_ID[playerid], -1, String);

            Transferir_ID[playerid] = -1;

        }
        else
            ShowPlayerDialog(playerid, DIALOG_TRANSFERIR_PEGAR_ID, DIALOG_STYLE_INPUT, "Tranfкrencia", "No campo abaixo digite o ID do jogador que receberб determinada quantia!\n", "Prуximo", "Fechar");

    }
    return 1;
}

public OnPlayerConnect(playerid) {

    Transferir_ID[playerid] = -1;
    return 1;
}

1 postagem basta!