[Klayton]

Hello samp, I have makea script account with two characters, but when I connect, I just see one character, but I have two.

Screenshot InGame: http://prntscr.com/hxkeab

Script: https://pastebin.com/Qpc6hnEJ

Screenshot database: http://prntscr.com/hxkdz9

[Mikro]

You are only showing the first result of your query. What you need is a loop through all the rows. It would be something along the lines of this:

Code:

...

new name[64];
for(new i; i < rows; i++)
{
    cache_get_field_content(i, "username", name);
    format(string, sizeof(string),"Personnage: {FFFFFF}%s", name);
    SendClientMessage(playerid, -1, string);
}

...

[Klayton]

Oh yeah thanks bro +rep

[Mikro]

No problem, good luck!

[Klayton]

Just a last question, I have try in dialog, but I have just one account of my all accounts


http://prntscr.com/hxmq37


https://pastebin.com/vGNUMhHW

[Mikro]

You want to build the dialog content in a string. Now you are technically opening multiple dialogs with the same id and only one item. In the loop the content is being build, after the loop that build content is displayed in the dialog. Should be something like:

Code:

...

new content[500];
for(new i; i < rows; i++)
{
    cache_get_field_content(i, "username", name);
    format(string, sizeof(string),"Personnage: {FFFFFF}%s", name);
    SendClientMessage(playerid, -1, string);
           
    format(content, sizeof(content), "%s%s\n", content, name);
}

ShowPlayerDialog(playerid, DIALOG_CHOIX_PERSO, DIALOG_STYLE_LIST, "Choix de votre personnage", content, "Valider", "Quitter");

...

[Klayton]

Thank you very much man,

I make a function for load the name and stats of character, and when I choose and press one my character, he dosen't load

Can you explain me why don't correct please ?


My script: https://pastebin.com/8m9AMQQz

[Misiur]

Can you elaborate on "he doesn't load"? The "Load_Character" is not called at all, or the string in it returns some invalid data?

[Klayton]

Load_Character is called, but I have two characters on my account, and when I press on my second character, the name is loaded, is the name of my first character you know ?


I choose my second character "Frank_Galso": http://prntscr.com/hxpn9c
Name and account loaded is my first character "James_Laloute": http://prntscr.com/hxpni7

[Misiur]

Ah, I see. Hm, you are firing a query using "AccountInfo[playerid][Account_ID]" as the id. Can you show the code converting "listitem" from the dialog selecting account you want to inspect, into id you want selected?

[Klayton]

Sure, here: https://pastebin.com/fFGVJ3aB

[Misiur]

Ok.
So, first you load all characters:

Quote:

SELECT * FROM `server_characters` WHERE id_account=ACC_ID

And you display them in a dialog. However, when you pick a character from this list, you do the same query again, which loads unsurprisingly all characters again - then you grab data from row 0, which will always be the first character for this account. This is not what you want I presume.

Laziest fix would be just using offset in your query when choosing the character you want:

pawn Code:

// Make sure the response is not false, and listitem is a sane value first (it might be spoofed IIRC)!
mysql_format(dbhandle, query, sizeof(query), "SELECT * FROM `server_characters` WHERE id_account = %d LIMIT %d, 1", AccountInfo[playerid][Account_ID], listitem);
mysql_tquery(dbhandle, query, "Load_Character", "i", playerid);

However, issuing a query to the database (or reading from a file, or simply anything I/O related) is the slowest thing in your script. Even if it might look like just 2 lines of code, it will be slower than 5000 lines of PAWN code which does not fire any queries.

How to approach this?
I'm making an assumption that you don't want to store all characters the whole time user is logged in, if that's not the case, adjust accordingly.
You are going to need a new array for temporarily holding your characters data (you can purge it right after you no longer need it or when user logs out, whenever). From the code you've posted these fields will be required:

pawn Code:

// You might already have this defined somewhere
#define MAX_CHARACTERS_PER_ACCOUNT 3

// Add this
enum E_CHARACTER_PREVIEW {
  E_CHARACTER_PREVIEW_ID,  
  E_CHARACTER_PREVIEW_SKIN,  
  E_CHARACTER_PREVIEW_STATUS,  
  E_CHARACTER_PREVIEW_NAME[MAX_PLAYER_NAME + 1]  
}
new TemporaryCharacterInfo[MAX_PLAYERS][MAX_CHARACTERS_PER_ACCOUNT][E_CHARACTER_PREVIEW];

Ya, that will take a lot of cells, but it's standard memory/CPU cycles tradeoff (also can someone remind me if standard PAWN compiler allows 4D).

Then in your ChoixPersonnage just load the data into your array (in a loop going through all rows WITH check if row < MAX_CHARACTERS_PER_ACCOUNT):

pawn Code:

TemporaryCharacterInfo[playerid][row][E_CHARACTER_PREVIEW_ID] = cache_get_field_content_int(row, "id");
TemporaryCharacterInfo[playerid][row][E_CHARACTER_PREVIEW_SKIN] = cache_get_field_content_int(row, "skin_player");
TemporaryCharacterInfo[playerid][row][E_CHARACTER_PREVIEW_STATUS] = cache_get_field_content_int(row, "statut_character");
cache_get_field_content(row, "username", TemporaryCharacterInfo[playerid][row][E_CHARACTER_PREVIEW_NAME], MAX_PLAYER_NAME + 1);

Bam, now you have all characters loaded into the array. Now you don't even need "Load_Character" public function anymore as you don't have to execute threaded query!

Than in OnDialogBlahBlah

pawn Code:

// I assume you have !response check defined somewhere else
case DIALOG_CHOIX_PERSO:
{
    if (!(0 < listitem < MAX_CHARACTERS_PER_PLAYER)) {
      return SCM(playerid, -1, "Invalid character selected");
    }  

    new cid = TemporaryCharacterInfo[playerid][listitem][E_CHARACTER_PREVIEW_ID];
    new skinid = TemporaryCharacterInfo[playerid][listitem][E_CHARACTER_PREVIEW_SKIN];
    new statutcompte = TemporaryCharacterInfo[playerid][listitem][E_CHARACTER_PREVIEW_STATUS];
    new name[MAX_PLAYER_NAME + 1];
    strcpy(name, TemporaryCharacterInfo[playerid][listitem][E_CHARACTER_PREVIEW_NAME]);

    format(string, sizeof(string), "Votre personnage (n°%d) avec le pseudo %s portant le skin %d | Statut du personnage: %d", cid, name, skinid, statutcompte);
    SendClientMessage(playerid, COLOR_ADMIN, string);
    SendClientMessage(playerid, COLOR_ADMIN, "____________________________________");

    format(string2, sizeof(string2), "Voici un aperзu des stats de votre personnage choisi:\n\nID: %d\nPersonnage: %s\nSkin: %d\nStatut du personnage: %d", cid, name, skinid, statutcompte);
    ShowPlayerDialog(playerid, DIALOG_INFO_PERSO, DIALOG_STYLE_MSGBOX, "Information concernant votre personnage", string2, "SPAWN", "");
}

Voila! Remember to empty this array for playerid on disconnect, otherwise when someone logs in with, say, less characters than current player, they will see remaining character accounts, and you certainly don't want that!

As an excercise to you, how would you handle "back" button in your DIALOG_INFO_PERSO to avoid loading all characters again?
Also, if you wanted to add pagination then code will change significantly, keep that in mind.

[Klayton]

Thanks lot boss.