It may happen when to use sscanf and you try to /pm a non-connected player (or use any other command which accepts a playerid).
Trying to /pm me using "/pm xPower blabla" would result in getting INVALID_PLAYER_ID returned by sscanf to indicate no player was found with that name.
So, right after sscanf, ALWAYS check if the returned playerid is below MAX_PLAYERS.
If the value is valid, continue the command.
If it's invalid, exit the command immediately using a "return SendClientMessage(playerid, -1, "That player isn't online");".
If you just use the value returned to access an array (PlayerData array for example), you'll get that error.
pawn Код:
// Freeze a player
COMMAND:freeze(playerid, params[])
{
// If the player has an insufficient admin-level (he needs level 1), exit the command
if (APlayerData[playerid][AdminLevel] < 1) return SendClientMessage(playerid, 0xFFFFFFFF, "{FF0000}Only admins level 1 and higher can use this command");
// Setup local variables
new Msg[128], OtherPlayer, Duration;
// Split the parameters
if (sscanf(params, "ui", OtherPlayer, Duration)) return SendClientMessage(playerid, 0xFF0000AA, "Usage: \"/freeze <OtherPlayer> <Duration>\"");
// If the other player has an invalid ID (sscanf returns 65535 as playerid if the player cannot be found), exit the command
if (OtherPlayer >= MAX_PLAYERS) return SendClientMessage(playerid, 0xFFFFFFFF, "{FF0000}That player is not online");
// If the other player is still in class selection, exit the command
if (Player_InClassSelection(OtherPlayer) == 1) return SendClientMessage(playerid, 0xFFFFFFFF, "{FF0000}That player is still in class-selection and cannot be frozen");
// If an invalid duration was given (0 or lower), exit the command
if (Duration <= 0) return SendClientMessage(playerid, 0xFFFFFFFF, "{FF0000}Duration must be minimum 1 second");
// Freeze the given player for the specified duration (store the freezetime and freeze the player)
APlayerData[OtherPlayer][FreezeTime] = Duration;
TogglePlayerControllable(OtherPlayer, 0);
// Let the other player know he has been frozen and by who
format(Msg, sizeof(Msg), "{FF0000}You've been frozen for {FFFF00}%i{FF0000} seconds by {FFFF00}%s", Duration, APlayerData[playerid][Name]);
SendClientMessage(OtherPlayer, 0xFFFFFFFF, Msg);
// Let the admin know who's been frozen
format(Msg, sizeof(Msg), "{00FF00}You have frozen {FFFF00}%s", APlayerData[OtherPlayer][Name]);
SendClientMessage(playerid, 0xFFFFFFFF, Msg);
// Now the global timer takes over to un-freeze him when the timer has reached 0 (also the freeze-time is saved automatically by the global timer)
// Let the server know that this was a valid command
return 1;
}
Like this (copy/pasted example from my own script).
