[Dardo]

Hola amigos de forum samp tengo un problema con el sscanf parece.Pase un fs al gamemode y funciona todo bien pero en la consola me sale

Код:

sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.
sscanf warning: Unenclosed specifier parameters are deprecated, consider using something like p<,>.

eso sale al agregar esto en ongamemodeinit.

pawn Код:

LoadVehicles();
LoadDealerships();
LoadFuelStations();
for(new i=0; i < MAX_PLAYERS; i++)
{
if(IsPlayerConnected(i))
{
OnPlayerConnect(i);
}
}
for(new i=1; i < MAX_DVEHICLES; i++)
{
UpdateVehicle(i, 0);
}
for(new i=1; i < MAX_DEALERSHIPS; i++)
{
UpdateDealership(i, 0);
}
for(new i=1; i < MAX_FUEL_STATIONS; i++)
{
UpdateFuelStation(i, 0);
}

Que podra ser? desde ya muchas gracias

[oOFotherOo]

Amigo pase la linea donde se ejecuta la funciуn sscanf ya que este error se debe a un mal uso de parametros en sscanf.

Un saludo.

[Dardo]

Quote:

Originally Posted by oOFotherOo Amigo pase la linea donde se ejecuta la funciуn sscanf ya que este error se debe a un mal uso de parametros en sscanf. Un saludo.

encontre esto que utiliza sscanf

pawn Код:

LoadDealerships()
{
    new File:handle, count;
    new filename[64], line[256], s, key[64];
    for(new i=1; i < MAX_DEALERSHIPS; i++)
    {
        format(filename, sizeof(filename), DEALERSHIP_FILE_PATH "d%d.ini", i);
        if(!fexist(filename)) continue;
        handle = fopen(filename, io_read);
        while(fread(handle, line))
        {
            StripNL(line);
            s = strfind(line, "=");
            if(!line[0] || s < 1) continue;
            strmid(key, line, 0, s++);
            if(strcmp(key, "Created") == 0) DealershipCreated[i] = strval(line[s]);
            else if(strcmp(key, "Pos") == 0) sscanf(line[s], "p,fff", DealershipPos[i][0],
                DealershipPos[i][1], DealershipPos[i][2]);
        }
        fclose(handle);
        if(DealershipCreated[i]) count++;
    }
    printf("  Loaded %d dealerships", count);
}

pawn Код:

LoadFuelStations()
{
    new File:handle, count;
    new filename[64], line[256], s, key[64];
    for(new i=1; i < MAX_FUEL_STATIONS; i++)
    {
        format(filename, sizeof(filename), FUEL_STATION_FILE_PATH "f%d.ini", i);
        if(!fexist(filename)) continue;
        handle = fopen(filename, io_read);
        while(fread(handle, line))
        {
            StripNL(line);
            s = strfind(line, "=");
            if(!line[0] || s < 1) continue;
            strmid(key, line, 0, s++);
            if(strcmp(key, "Created") == 0) FuelStationCreated[i] = strval(line[s]);
            else if(strcmp(key, "Pos") == 0) sscanf(line[s], "p,fff", FuelStationPos[i][0],
                FuelStationPos[i][1], FuelStationPos[i][2]);
        }
        fclose(handle);
        if(FuelStationCreated[i]) count++;
    }
    printf("  Loaded %d fuel stations", count);
}

pawn Код:

LoadVehicles()
{
    new string[64];
    new File:handle, count;
    new filename[64], line[256], s, key[64];
    for(new i=1; i < MAX_DVEHICLES; i++)
    {
        format(filename, sizeof(filename), VEHICLE_FILE_PATH "v%d.ini", i);
        if(!fexist(filename)) continue;
        handle = fopen(filename, io_read);
        while(fread(handle, line))
        {
            StripNL(line);
            s = strfind(line, "=");
            if(!line[0] || s < 1) continue;
            strmid(key, line, 0, s++);
            if(strcmp(key, "Created") == 0) VehicleCreated[i] = strval(line[s]);
            else if(strcmp(key, "Model") == 0) VehicleModel[i] = strval(line[s]);
            else if(strcmp(key, "Pos") == 0) sscanf(line[s], "p,ffff", VehiclePos[i][0], VehiclePos[i][1],
                VehiclePos[i][2], VehiclePos[i][3]);
            else if(strcmp(key, "Colors") == 0) sscanf(line[s], "p,dd", VehicleColor[i][0], VehicleColor[i][1]);
            else if(strcmp(key, "Interior") == 0) VehicleInterior[i] = strval(line[s]);
            else if(strcmp(key, "VirtualWorld") == 0) VehicleWorld[i] = strval(line[s]);
            else if(strcmp(key, "Owner") == 0) strmid(VehicleOwner[i], line, s, sizeof(line));
            else if(strcmp(key, "NumberPlate") == 0) strmid(VehicleNumberPlate[i], line, s, sizeof(line));
            else if(strcmp(key, "Value") == 0) VehicleValue[i] = strval(line[s]);
            else if(strcmp(key, "Lock") == 0) VehicleLock[i] = strval(line[s]);
            else if(strcmp(key, "Alarm") == 0) VehicleAlarm[i] = strval(line[s]);
            else if(strcmp(key, "Paintjob") == 0) VehiclePaintjob[i] = strval(line[s]);
            else
            {
                for(new t=0; t < sizeof(VehicleTrunk[]); t++)
                {
                    format(string, sizeof(string), "Trunk%d", t+1);
                    if(strcmp(key, string) == 0) sscanf(line[s], "p,dd", VehicleTrunk[i][t][0], VehicleTrunk[i][t][1]);
                }
                for(new m=0; m < sizeof(VehicleMods[]); m++)
                {
                    format(string, sizeof(string), "Mod%d", m);
                    if(strcmp(key, string) == 0) VehicleMods[i][m] = strval(line[s]);
                }
            }
        }
        fclose(handle);
        if(VehicleCreated[i]) count++;
    }
    printf("  Loaded %d vehicles", count);
}

[oOFotherOo]

Amigo pruebe reemplazando el parametro "p," por "p<,>".

Un saludo.

[Dardo]

Quote:

Originally Posted by oOFotherOo Amigo pruebe reemplazando el parametro "p," por "p<,>". Un saludo.

Muchisimas gracias ya no sale eso en la consola