[B-rian]

Hello guys! I want to request a Command where if I type /v it spawns a car and /vdestroy destroys it.

I also want a command that ONLY admins can use wich is /respawnall, wich despawns all cars spawned by players and respawns server side cars.

Can anybody find/do that script? I've been looking and the ones I found are either Filterscripts or plugins... I would like just a plain Pawno code.

This is not demanding. It's asking. Thank you

[MarinacMrcina]

I just did mine a few minutes ago

You will need sscanf and zcmd includes for this!

pawn Код:

CMD:v(playerid, params[]) 
{
    if(!IsPlayerAdmin(playerid) && GetPVarInt(playerid, "Admin") < 2) return SendClientMessage(playerid,RED,"You are not RCON or Head admin!");
    else
    {
        new vehid;new b1;new b2;
        if(sscanf(params, "iii", vehid,b1,b2)) SendClientMessage(playerid, RED, "Use: /v [car id] [color 1] [color 2]");
        else if(vehid < 400 || vehid > 611) return SendClientMessage(playerid, RED, "Wrong car id!");
        else if(vehid == 425 || vehid == 520 || vehid == 537 || vehid == 538 || vehid == 569 || vehid == 570 || vehid == 590) return SendClientMessage(playerid, CRVENA, "You can't spawn a hydra and the rest military vehicles!");
        else if(b2 <=0 || b2 >= 252) return SendClientMessage(playerid, RED, "Wrong color 1 id!");
        else if(b1 <=0 || b1 >= 252) return SendClientMessage(playerid, RED, "Wrong color 2 id!");
        else
        {
            new Float:x, Float:y, Float:z;new Float:kut;
            GetPlayerPos(playerid, x, y, z);
            GetPlayerFacingAngle(playerid, kut);
            CreateVehicle(vehid, x + 3, y + 1, z, kut, b1, b2, -1);
            SendClientMessage(playerid, GREEN, "You have spawned a car near you!");
        }
    }
    return 1;
}

[Avi57]

/v script :

Код:

/*
.:[Vehicle Spawner V. 1.1]:. by x96664
Please don't remove my credits!
Use /v to open vehicle dialog.
-Features in 1.1:
1.Anti multi vehicle spawning ( it deletes the previous car when you spawn new one).
*/
#include <a_samp>
#define dcmd(%1,%2,%3) if (!strcmp((%3)[1], #%1, true, (%2)) && ((((%3)[(%2) + 1] == '\0') && (dcmd_%1(playerid, ""))) || (((%3)[(%2) + 1] == ' ') && (dcmd_%1(playerid, (%3)[(%2) + 2]))))) return 1
//Colors
#define COLOR_WHITE 0xFFFFFFAA
#define COLOR_RED 0xff0000a7
//RC vehicles
#define RC_BANDIT	441
#define RC_BARON	464
#define RC_GOBLIN	501
#define RC_RAIDER	465
#define D_TRAM		449
#define RC_TIGER	564
#define RC_CAM		594
//Dialogs                           I'm using bigger dialog ids to don't make conflict with your server dialogs.
#define Dialog_Unique_Vehicle 10000
#define Dialog_Trailers_Vehicle 10001
#define Dialog_Boats_Vehicle 10002
#define Dialog_Station_Vehicle 10003
#define Dialog_Sport_Vehicle 10004
#define Dialog_Saloon_Vehicle 10005
#define Dialog_Public_Service_Vehicle 10006
#define Dialog_Off-Road_Vehicle 10007
#define Dialog_LowRyder_Vehicle 10008
#define Dialog_Industry_Vehicle 10009
#define Dialog_Convertable_Vehicle 10010
#define Dialog_Bike_Vehicle 10011
#define Dialog_Helicopters 10012
#define Dialog_Airplanes 10013
#define Dialog_Rc_Vehicle 10014
#define Dialog_Vehicle 10015
//Defines
#define MAX_PLAYERVEHICLES 1
#define VehicleSpawnerLimit 1
//Forward
forward VehicleSpawner(playerid,model);
forward VehicleDeleter(vehicleid);
forward VehicleReseter(vehicleid);
forward VehicleSpawnerLimiter(playerid);
//new
new VehicleSpawn[MAX_PLAYERS];
new PlayerVehicle[MAX_PLAYERS][MAX_PLAYERVEHICLES];
new Turn[MAX_PLAYERS];
//vehicles
new Airplanes[] = { 592, 577, 511, 512, 593, 520, 553, 476, 519, 460, 513 };
new Helicopters[] = { 548, 425, 417, 487, 488, 497, 563, 447, 469 };
new Bikes[] = { 581, 509, 481, 462, 521, 463, 510, 522, 461, 448, 471, 468, 586 };
new Convertibles[] = { 480, 533, 439, 555 };
new Industrials[] = { 499, 422, 482, 498, 609, 524, 578, 455, 403, 414, 582, 443, 514, 413, 515, 440, 543, 605, 459, 531, 408, 552, 478, 456, 554 };
new Lowriders[] = { 536, 575, 534, 567, 535, 566, 576, 412 };
new Offroad[] = { 568, 424, 573, 579, 400, 500, 444, 556, 557, 470, 489, 505, 495 };
new Pulic_Services[] = { 416, 433, 431, 438, 437, 523, 427, 490, 528, 407, 544, 596, 598, 597, 599, 432, 601, 420 };
new Saloons[] = { 445, 504, 401, 518, 527, 542, 507, 562, 585, 419, 526, 604, 466, 492, 474, 546, 517, 410, 551, 516, 467, 600, 426, 436, 547, 405, 580, 560, 550, 549, 540, 491, 529, 421 };
new Sport[] = { 602, 429, 496, 402, 541, 415, 589, 587, 565, 494, 502, 503, 411, 559, 603, 475, 506, 451, 558, 477 };
new Station[] = { 418, 404, 479, 458, 561 };
new Boats[] = { 472, 473, 493, 595, 484, 430, 453, 452, 446, 454 };
new Trailers[] = { 435, 450, 591, 606, 607, 610, 569, 590, 584, 570, 608, 611 };
new Unique[] = { 485, 537, 457, 483, 508, 532, 486, 406, 530, 538, 434, 545, 588, 571, 572, 423, 442, 428, 409, 574, 449, 525, 583, 539 };
new RC_Vehicles[] = { 441, 464, 465, 501, 564, 594 };

public OnFilterScriptInit()
{
	print("\n--------------------------------------");
	print("|Vehicle spawner by x96664 loaded!  |");
	print("--------------------------------------\n");
	SetTimer("VehicleSpawnLimiter", 1000, true);
	return 1;
}

public OnFilterScriptExit()
{	print("\n--------------------------------------");
	print("|Vehicle spawner by x96664 unloaded!  |");
	print("--------------------------------------\n");
	return 1;
}

public OnPlayerCommandText(playerid, cmdtext[])
{
dcmd(v, 1,cmdtext);
return 0;
}
dcmd_v(playerid, params[])
{
#pragma unused params
ShowVehicleDialog(playerid);
return 1;
}

public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{

    if(newkeys == KEY_SECONDARY_ATTACK ){
        if(!IsPlayerInAnyVehicle(playerid)){
            new Float:x, Float:y, Float:z, vehicle;
            GetPlayerPos(playerid, x, y, z );
            GetVehicleWithinDistance(playerid, x, y, z, 20.0, vehicle);

            if(IsVehicleRc(vehicle)){
              PutPlayerInVehicle(playerid, vehicle, 0);
            }
        }

        else {
            new vehicleID = GetPlayerVehicleID(playerid);
            if(IsVehicleRc(vehicleID) || GetVehicleModel(vehicleID) == RC_CAM){
              if(GetVehicleModel(vehicleID) != D_TRAM){
                new Float:x, Float:y, Float:z;
                GetPlayerPos(playerid, x, y, z);
                SetPlayerPos(playerid, x+0.5, y, z+1.0);
                }
            }
        }
    }
}
GetVehicleWithinDistance( playerid, Float:x1, Float:y1, Float:z1, Float:dist, &veh){
    for(new i = 1; i < MAX_VEHICLES; i++){
        if(GetVehicleModel(i) > 0){
            if(GetPlayerVehicleID(playerid) != i ){
            new Float:x, Float:y, Float:z;
            new Float:x2, Float:y2, Float:z2;
            GetVehiclePos(i, x, y, z);
            x2 = x1 - x; y2 = y1 - y; z2 = z1 - z;
            new Float:vDist = (x2*x2+y2*y2+z2*z2);
            if( vDist < dist){
            veh = i;
            dist = vDist;
                }
            }
        }
    }
}
IsVehicleRc( vehicleid ){
  new model = GetVehicleModel(vehicleid);
  switch(model){
  case RC_GOBLIN, RC_BARON, RC_BANDIT, RC_RAIDER, RC_TIGER: return 1;
  default: return 0;
    }

  return 0;
}

public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[])
{
if(dialogid== Dialog_Vehicle)
{
if ( response==1 )
{
if(listitem==0)ShowPlayerDialog( playerid, Dialog_Airplanes, 2, "{ffffff}Airplanes:", "Andromada\nAT-400\nBeagle\nCropduster\nDodo\nNevada\nRustler\nShamal\nSkimmer\nStuntplane", "Spawn", "Back" );
if(listitem==1)ShowPlayerDialog( playerid, Dialog_Helicopters, 2, "{ffffff}Helicopters:", "Cargobob\nHunter\nLeviathan\nMaverick\nNews Maverick\nPolice Maverick\nRaindance\nSeasparrow\nSparrow", "Spawn", "Back" );
if(listitem==2)ShowPlayerDialog( playerid, Dialog_Bike_Vehicle, 2, "{ffffff}Bikes:", "BF-400\nBike\nBMX\nFaggio\nFCR-900\nFreeway\nMountain Bike\nNRG-500\nPCJ-600\nPizzaboy\nQuad\nSanchez\nWayfarer", "Spawn", "Back" );
if(listitem==3)ShowPlayerDialog( playerid, Dialog_Convertable_Vehicle, 2, "{ffffff}Convertibles:", "Comet\nFeltzer\nStallion\nWindsor", "Spawn", "Back" );
if(listitem==4)ShowPlayerDialog( playerid, Dialog_Industry_Vehicle, 2, "{ffffff}Industrial:", "Benson\nBobcat\nBurrito\nBoxville\nBoxburg\nCement Truck\nDFT-30\nFlatbed\nLinerunner\nMule\nNewsvan\nPacker\nPetrol Tanker\nPony\nRoadtrain\nRumpo\nSadler\nSadler Shit\nTopfun\nTractor\nTrashmaster\nUtility Van\nWalton\nYankee\nYosemite", "Spawn", "Back" );
if(listitem==5)ShowPlayerDialog( playerid, Dialog_LowRyder_Vehicle, 2, "{ffffff}Lowriders:", "Blade\nBroadway\nRemington\nSavanna\nSlamvan\nTahoma\nTornado\nVoodoo", "Spawn", "Back" );
if(listitem==6)ShowPlayerDialog( playerid, Dialog_Off-Road_Vehicle, 2, "{ffffff}Off Road:", "Bandito\nBF Injection\nDune\nHuntley\nLandstalker\nMesa\nMonster\nMonster A\nMonster B\nPatriot\nRancher A\nRancher B\nSandking", "Spawn", "Back" );
if(listitem==7)ShowPlayerDialog( playerid, Dialog_Public_Service_Vehicle, 2, "{ffffff}Public Service Vehicles:", "Ambulance\nBarracks\nBus\nCabbie\nCoach\nCop Bike (HPV-1000)\nEnforcer\nFBI Rancher\nFBI Truck\nFiretruck\nFiretruck LA\nPolice Car (LSPD)\nPolice Car (LVPD)\nPolice Car (SFPD)\nRanger\nRhino\nS.W.A.T\nTaxi", "Spawn", "Back" );
if(listitem==8)ShowPlayerDialog( playerid, Dialog_Saloon_Vehicle, 2, "{ffffff}Saloons:", "Admiral\nBlooDialog_Weapon_Riflesng Banger\nBravura\nBuccaneer\nCadrona\nClover\nElegant\nElegy\nEmperor\nEsperanto\nFortune\nGlendale Shit\nGlendale\nGreenwood\nHermes\nIntruder\nMajestic\nManana\nMerit\nNebula\nOceanic\nPicador\nPremier\nPrevion\nPrimo\nSentinel\nStafford\nSultan\nSunrise\nTampa\nVincent\nVirgo\nWillard\nWashington", "Spawn", "Back" );
if(listitem==9)ShowPlayerDialog( playerid, Dialog_Sport_Vehicle, 2, "{ffffff}Sport Vehicles:", "Alpha\nBanshee\nBlista Compact\nBuffalo\nBullet\nCheetah\nClub\nEuros\nFlash\nHotring Racer\nHotring Racer A\nHotring Racer B\nInfernus\nJester\nPhoenix\nSabre\nSuper GT\nTurismo\nUranus\nZR-350", "Spawn", "Back" );
if(listitem==10)ShowPlayerDialog( playerid, Dialog_Station_Vehicle, 2, "{ffffff}Station Wagons:", "Moonbeam\nPerenniel\nRegina\nSolair\nStratum", "Spawn", "Back" );
if(listitem==11)ShowPlayerDialog( playerid, Dialog_Boats_Vehicle, 2, "{ffffff}Boats:", "Coastguard\nDinghy\nJetmax\nLaunch\nMarquis\nPredator\nReefer\nSpeeder\nSquallo\nTropic", "Spawn", "Back" );
if(listitem==12)ShowPlayerDialog( playerid, Dialog_Trailers_Vehicle, 2, "{ffffff}Trailers:", "Article Trailer\nArticle Trailer 2\nArticle Trailer 3\nBaggage Trailer A\nBaggage Trailer B\nFarm Trailer\nFreight Flat Trailer (Train)\nFreight Box Trailer (Train)\nPetrol Trailer\nStreak Trailer (Train)\nStairs Trailer\nUtility Trailer", "Spawn", "Back" );
if(listitem==13)ShowPlayerDialog( playerid, Dialog_Unique_Vehicle, 2, "{ffffff}Unique Vehicles:", "Baggage\nBrownstreak (Train)\nCaddy\nCamper\nCamper A\nCombine Harvester\nDozer\nDumper\nForklift\nFreight (Train)\nHotknife\nHustler\nHotdog\nKart\nMower\nMr Whoopee\nRomero\nSecuricar\nStretch\nSweeper\nTram\nTowtruck\nTug\nVortex", "Spawn", "Back" );
if(listitem==14)ShowPlayerDialog( playerid, Dialog_Rc_Vehicle, 2, "{ffffff}RC Vehicles:", "RC Bandit\nRC Baron\nRC Raider\nRC Goblin\nRC Tiger\nRC Cam", "Spawn", "Back" );
}
}
if(dialogid== Dialog_Airplanes){if ( response ){
VehicleSpawner(playerid,Airplanes[ listitem ]);}}
if(dialogid== Dialog_Helicopters){
if ( response ){
VehicleSpawner(playerid,Helicopters[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Bike_Vehicle){
if ( response ){
VehicleSpawner(playerid,Bikes[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Convertable_Vehicle){
if ( response ){
VehicleSpawner(playerid,Convertibles[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Industry_Vehicle){
if ( response ){
VehicleSpawner(playerid,Industrials[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_LowRyder_Vehicle){
if ( response ){
VehicleSpawner(playerid,Lowriders[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Off-Road_Vehicle){
if ( response ){
VehicleSpawner(playerid,Offroad[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Public_Service_Vehicle){
if ( response ){
VehicleSpawner(playerid,Pulic_Services[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Saloon_Vehicle){
if ( response ){
VehicleSpawner(playerid,Saloons[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Sport_Vehicle){
if ( response ){
VehicleSpawner(playerid,Sport[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Station_Vehicle){
if ( response ){
VehicleSpawner(playerid,Station[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Boats_Vehicle){
if ( response ){
VehicleSpawner(playerid,Boats[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Trailers_Vehicle){
if ( response ){
VehicleSpawner(playerid,Trailers[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Unique_Vehicle){
if ( response ){
VehicleSpawner(playerid,Unique[ listitem ]);
}else ShowVehicleDialog(playerid);
}
if(dialogid== Dialog_Rc_Vehicle){
if ( response ){
VehicleSpawner(playerid,RC_Vehicles[ listitem ]);
}else ShowVehicleDialog(playerid);
}
return 1;
}

stock ShowVehicleDialog(playerid)
{
ShowPlayerDialog(playerid, Dialog_Vehicle, 2, "{ffffff}Vehicle categories:", "Airplanes\nHelicopters\nBikes\nConvertibles\nIndustrial\nLowriders\nOff Road\nPublic Service Vehicles\nSaloons\nSport Vehicles\nStation Wagons\nBoats\nTrailers\nUnique Vehicles\nRC Vehicles", "Select", "Back" );
}

public VehicleSpawner(playerid,model){
	if(IsPlayerInAnyVehicle(playerid)){
		SendClientMessage(playerid, COLOR_RED, "Error: You're already in vehicle!");
 	}
 	else{
	if(VehicleSpawn[playerid]==0){
	new Float:x,Float:y,Float:z,Float:a, vehicleid;
    GetPlayerPos(playerid,x,y,z);
    GetPlayerFacingAngle(playerid,a);
    vehicleid = CreateVehicle(model,x+1,y+1,z,a,-1,-1,-1);
    PutPlayerInVehicle(playerid, vehicleid, 0);
    SetVehicleHealth(vehicleid,  1000.0);
    LinkVehicleToInterior(vehicleid, GetPlayerInterior(playerid));
	for(new i=0;i<MAX_PLAYERVEHICLES;i++){
    if(Turn[playerid]==MAX_PLAYERVEHICLES){
    VehicleDeleter(PlayerVehicle[playerid][0]);
    new b=MAX_PLAYERVEHICLES-1;
    for(new c=0;c<b;c++){
    new A=c+1;
    PlayerVehicle[playerid][c]=PlayerVehicle[playerid][A];
    }
    PlayerVehicle[playerid][b]=0;
    Turn[playerid]--;
	}
	if(!PlayerVehicle[playerid][i]){
	PlayerVehicle[playerid][i]=vehicleid;
	Turn[playerid]++;
	break;
    }
  }
}
		else{
		 	new string[256];
			format(string, sizeof(string), "Please wait %d sec. to spawn again a vehicle!", VehicleSpawn[playerid]);
			SendClientMessage(playerid,COLOR_RED, string);
		}
	}
}
public VehicleDeleter(vehicleid)
{
    for(new i=0;i<MAX_PLAYERS;i++){
        new Float:X,Float:Y,Float:Z;
    	if(IsPlayerInVehicle(i, vehicleid)){
    	    RemovePlayerFromVehicle(i);
    	    GetPlayerPos(i,X,Y,Z);
        	SetPlayerPos(i,X,Y+3,Z);
	    }
	    SetVehicleParamsForPlayer(vehicleid,i,0,1);
	}
    SetTimerEx("VehicleReseter",2000,0,"i",vehicleid);
}

public VehicleReseter(vehicleid)
{
    DestroyVehicle(vehicleid);
}

public VehicleSpawnerLimiter(){
	new i;
	for(i=0;i<=MAX_PLAYERS;i++){
	    if(VehicleSpawn[i]>0){
   	 		VehicleSpawn[i]--;
	    }
	}
}
public OnVehicleSpawn(vehicleid)
{
	for(new i=0;i<MAX_PLAYERS;i++)
	{
	    for(new u=0;u<MAX_PLAYERVEHICLES;u++)
	    {
	        if(vehicleid==PlayerVehicle[i][u])
			{
			    VehicleDeleter(vehicleid);
		        PlayerVehicle[i][u]=0;
				Turn[i]--;
	        }
	    }
	}
	return 1;
}

[B-rian]

Avi, is there a specific place i need to put the code in Pawno? or can I just lay it somewhere?

[A7X_CEEJAY]

Quote:

Originally Posted by B-rian Avi, is there a specific place i need to put the code in Pawno? or can I just lay it somewhere?

My friend, that is a filterscript.

Make a new .pwn file - Paste it in, save it as soemthing E.G "Vehsystem", Compile it (F5), then once the AMX is there, drag it over int oyour server - And in your server.cfg, on the 'filsterscripts' add the 'Vehsystem' there, or whatever you called it and re-run your server


Also, respawning cars;

pawn Код:

CMD:respawn(playerid, params[])
{
    new string[128], veh;
    if(!IsPlayerLoggedIn(playerid)) return SendClientMessage(playerid, COLOR_GREY, "You need to login first before using any command.");
    if(PlayerInfo[playerid][pAdmin] < 4) return SendClientMessage(playerid, COLOR_GREY, "You are not authorized to use this command.");
//     if(!aDuty[playerid]) return SendClientMessage(playerid, COLOR_GREY, "You are not on admin duty.");
    if(!strcmp(params, "all", true))
    {
        for(new i=0; i<MAX_VEHICLES; i++)
        {
            if(i != NPCBus)
            {
                new vehs;
                foreach(Player, x)
                {
                    if(GetPlayerVehicleID(x) == i)
                    {
                        vehs = 1;
                    }
                }
                if(!vehs)
                {
                    SetVehicleToRespawn(i);
                }
                vehs = 0;
            }
        }
        format(string, sizeof(string), "AdmCmd: %s has respawned all unused vehicles.", RPN(playerid));
        SendClientMessageToAll(COLOR_LIGHTRED, string);
        return 1;
    }
    if(sscanf(params, "i", veh)) return SendClientMessage(playerid, COLOR_WHITE, "USAGE: /respawn [vehicleid/all]");
    SetVehicleToRespawn(veh);
    format(string, sizeof(string), "AdmWarn: %s has respawned vehicle ID %d.", RPN(playerid), veh);
    SendAdminMessage(COLOR_DARKRED, 1, string);
    return 1;
}

Usage:
/respawn (in a car will respawn the car you are in)
/respawn [VEHICLEID] (when not in a car, will respawn the specified ID (/dl can be used to get the ID's of cars)
/respawn all = Does as it says on the tin.

[Randy More]

Simple codes, but should do the trick.
Considering the enum. of the player data is the "PlayerInfo" as the common used..

pawn Код:

// Anywhere, recommended to be after the variables, not in a function or a callback for sure.
enum pinfo
{
    Admin,
    SpawnedVehicle,
    HasVehicleSpawned,
}
new PlayerInfo[MAX_PLAYERS][pinfo];

// Same here, but recommended to be coded after the callbacks..
CMD:v(playerid, params[])
{
    new vehicleid, color1, color2, Float: x, Float: y, Float: z;
    if(sscanf(params,"iii", vehicleid, color1, color2)) return SendClientMessage(playerid, SOME_COLOR,"USAGE: /v [vehicleid] [color1] [color2]");
    GetPlayerPos(playerid, x, y, z);
    PlayerInfo[playerid][SpawnedVehicle] = CreateVehicle(vehicleid, x+2, y, z, 1.0, color1, color2, 1000);
    PlayerInfo[playerid][HasVehicleSpawned] = 1;
    return 1;
}

CMD:vdestroy(playerid, params[])
{
    if(!PlayerInfo[playerid][HasVehicleSpawned]) return SendClientMessage(playerid, SOME_COLOR,"ERROR: You don't have a spawned vehicle to destroy.");
    DestroyVehicle(PlayerInfo[playerid][SpawnedVehicle]);
    PlayerInfo[playerid][HasVehicleSpawned] = 0;
    return 1;
}

CMD:respawnvehicles(playerid, params[])
{
    if(!PlayerInfo[playerid][Admin]) return SendClientMessage(playerid, SOME_COLOR,"ERROR: You are not an administrator.");
    for(new v; v < MAX_VEHICLES; v++)
    {
        for(new i; i < MAX_PLAYERS; i++)
        {
            if(!GetPlayerVehicleID(i) == v)
            {
                 SetVehicleToRespawn(v);
                 SendClientMessageToAll(SOME_COLOR,"Warning: All unused vehicles have been respawned by an administrator.");
                return 1;
            }
        }
    }
    return 1;
}

[B-rian]

Uhhhh Im so confuuuuused T.T I just dont know how to install it!!! Or make it run, either.

EDIT: Ok i figured out the pawno part and stuff but I cant get the filterscript to load it says this on the server console:

Filterscripts
-----------------------
Loading vehspawner.amx...
Unable to load filterscript vehspawner.amx...

[A7X_CEEJAY]

Did you COMPILE it? (Open it in pawno and press F5)

[B-rian]

Here is what I did:

Copied the whole code that Avi gave me, then i opened Pawno then clicked new, deleted everything in it and just put the script in there. Then i compiled it. then i saved it has "vehspawner" in filterscripts folder then i went in server.cfg and put it on filterscripts has "vehspawner" then i started server and that pops up.

[B-rian]

GUYS I GOT IT WORKING! THANKS FOR ALL YOUR HELP!