[felipex]

Such as set wanted level for "such" player ID, such as "/wanted 1 1" Setwanted level of playerID = 1 in 1 level;
I've tried sa-mp wiki but nothing.

[RyDeR`]

I recommend to use a combination of sscanf and zcmd to create easy and fast commands.
Try to search on the forum for it.

Regards

[Grim_]

pawn Код:

cmd(wanted, playerid, params)
{
   new targetid, level;
   if(sscanf(params, "dd", targetid, level)) return 0; // They didn't type the full syntax
   else
   {
      if(targetid == INVALID_PLAYER_ID) return 0; // The player they're trying to do this to isn't connected
      if(level < 0 || level > 6) return 0; // Level is too high / low
      SetPlayerWantedLevel(targetid, level);
   }
   return 1;
}

[DJDhan]

There is a function called SetPlayerWantedLevel. Use it like so:

Код:

if(!strcmp(cmdtext,"/setwantedlevel",true))
{
	new tmp[64],tmp2[64],id,level,Index; //if you get "array size is too small" error, change the 64 cell size to 128 or 256

	if(!IsPlayerAdmin(playerid)) return SendClientMessage(playerid,0xffffffaa,"You are not authorised to use that command.");

	tmp = strtok(cmdtext,Index);
	tmp2 = strtok(cmdtext,Index);
	if(!strlen(tmp) || !strlen(tmp2)) return SendClientMessage(playerid,0xffffffaa,"USAGE: /setwantedlevel id level");

	id = strval(tmp);
        if(!IsPlayerConnected(id)) return SendClientMessage(playerid,0xffffffaa,"Player is not connected");

	level = strval(tmp2);
         if(level<0 || level>6) return SendClientMessage(playerid,0xffffffaa,"INVALID LEVEL [0-6]");
	SetPlayerWantedLevel(id,level);

	return 1;
}

EDIT: You can use either of the above solutions. Grim_'s code is shorter and nice.

[Grim_]

Lol, I was going to use strcmp() but I knew using zcmd would make it a lot quicker, so :P

[felipex]

For grim's got this error :

C:\Documents and Settings\felipe engine\Desktop\SERVER GTA SAMP\filterscripts\Gangness.pwn(504) : error 017: undefined symbol "sscanf"

and for yours DJ :

C:\Documents and Settings\felipe engine\Desktop\SERVER GTA SAMP\filterscripts\Gangness.pwn(507) : error 047: array sizes do not match, or destination array is too small
C:\Documents and Settings\felipe engine\Desktop\SERVER GTA SAMP\filterscripts\Gangness.pwn(50 : error 047: array sizes do not match, or destination array is too small

I had a code similar to yours DJ, and got same errors =d


EDIT : Didn't see your comment about my errorr of small array, changed for 256 and worked, ty

[iZN]

DJDhan codes Fixed*

pawn Код:

if(!strcmp(cmdtext,"/setwantedlevel",true))
{
    new tmp[128],tmp2[128],id,level,Index;

    if(!IsPlayerAdmin(playerid)) return SendClientMessage(playerid,0xffffffaa,"You are not authorised to use that command.");

    tmp = strtok(cmdtext,Index);
    tmp2 = strtok(cmdtext,Index);
    if(!strlen(tmp) || !strlen(tmp2)) return SendClientMessage(playerid,0xffffffaa,"USAGE: /setwantedlevel id level");

    id = strval(tmp);
        if(!IsPlayerConnected(id)) return SendClientMessage(playerid,0xffffffaa,"Player is not connected");

    level = strval(tmp2);
         if(level<0 || level>6) return SendClientMessage(playerid,0xffffffaa,"INVALID LEVEL [0-6]");
    SetPlayerWantedLevel(id,level);

    return 1;
}

For Grim_'s command error:
Add this in your script:

pawn Код:

stock sscanf(string[], format[], {Float,_}:...)
{
    #if defined isnull
        if (isnull(string))
    #else
        if (string[0] == 0 || (string[0] == 1 && string[1] == 0))
    #endif
        {
            return format[0];
        }
    #pragma tabsize 4
    new
        formatPos = 0,
        stringPos = 0,
        paramPos = 2,
        paramCount = numargs(),
        delim = ' ';
    while (string[stringPos] && string[stringPos] <= ' ')
    {
        stringPos++;
    }
    while (paramPos < paramCount && string[stringPos])
    {
        switch (format[formatPos++])
        {
            case '\0':
            {
                return 0;
            }
            case 'i', 'd':
            {
                new
                    neg = 1,
                    num = 0,
                    ch = string[stringPos];
                if (ch == '-')
                {
                    neg = -1;
                    ch = string[++stringPos];
                }
                do
                {
                    stringPos++;
                    if ('0' <= ch <= '9')
                    {
                        num = (num * 10) + (ch - '0');
                    }
                    else
                    {
                        return -1;
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num * neg);
            }
            case 'h', 'x':
            {
                new
                    num = 0,
                    ch = string[stringPos];
                do
                {
                    stringPos++;
                    switch (ch)
                    {
                        case 'x', 'X':
                        {
                            num = 0;
                            continue;
                        }
                        case '0' .. '9':
                        {
                            num = (num << 4) | (ch - '0');
                        }
                        case 'a' .. 'f':
                        {
                            num = (num << 4) | (ch - ('a' - 10));
                        }
                        case 'A' .. 'F':
                        {
                            num = (num << 4) | (ch - ('A' - 10));
                        }
                        default:
                        {
                            return -1;
                        }
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num);
            }
            case 'c':
            {
                setarg(paramPos, 0, string[stringPos++]);
            }
            case 'f':
            {

                new changestr[16], changepos = 0, strpos = stringPos;
                while(changepos < 16 && string[strpos] && string[strpos] != delim)
                {
                    changestr[changepos++] = string[strpos++];
                    }
                changestr[changepos] = '\0';
                setarg(paramPos,0,_:floatstr(changestr));
            }
            case 'p':
            {
                delim = format[formatPos++];
                continue;
            }
            case '\'':
            {
                new
                    end = formatPos - 1,
                    ch;
                while ((ch = format[++end]) && ch != '\'') {}
                if (!ch)
                {
                    return -1;
                }
                format[end] = '\0';
                if ((ch = strfind(string, format[formatPos], false, stringPos)) == -1)
                {
                    if (format[end + 1])
                    {
                        return -1;
                    }
                    return 0;
                }
                format[end] = '\'';
                stringPos = ch + (end - formatPos);
                formatPos = end + 1;
            }
            case 'u':
            {
                new
                    end = stringPos - 1,
                    id = 0,
                    bool:num = true,
                    ch;
                while ((ch = string[++end]) && ch != delim)
                {
                    if (num)
                    {
                        if ('0' <= ch <= '9')
                        {
                            id = (id * 10) + (ch - '0');
                        }
                        else
                        {
                            num = false;
                        }
                    }
                }
                if (num && IsPlayerConnected(id))
                {
                    setarg(paramPos, 0, id);
                }
                else
                {
                    #if !defined foreach
                        #define foreach(%1,%2) for (new %2 = 0; %2 < MAX_PLAYERS; %2++) if (IsPlayerConnected(%2))
                        #define __SSCANF_FOREACH__
                    #endif
                    string[end] = '\0';
                    num = false;
                    new
                        name[MAX_PLAYER_NAME];
                    id = end - stringPos;
                    foreach (Player, playerid)
                    {
                        GetPlayerName(playerid, name, sizeof (name));
                        if (!strcmp(name, string[stringPos], true, id))
                        {
                            setarg(paramPos, 0, playerid);
                            num = true;
                            break;
                        }
                    }
                    if (!num)
                    {
                        setarg(paramPos, 0, INVALID_PLAYER_ID);
                    }
                    string[end] = ch;
                    #if defined __SSCANF_FOREACH__
                        #undef foreach
                        #undef __SSCANF_FOREACH__
                    #endif
                }
                stringPos = end;
            }
            case 's', 'z':
            {
                new
                    i = 0,
                    ch;
                if (format[formatPos])
                {
                    while ((ch = string[stringPos++]) && ch != delim)
                    {
                        setarg(paramPos, i++, ch);
                    }
                    if (!i)
                    {
                        return -1;
                    }
                }
                else
                {
                    while ((ch = string[stringPos++]))
                    {
                        setarg(paramPos, i++, ch);
                    }
                }
                stringPos--;
                setarg(paramPos, i, '\0');
            }
            default:
            {
                continue;
            }
        }
        while (string[stringPos] && string[stringPos] != delim && string[stringPos] > ' ')
        {
            stringPos++;
        }
        while (string[stringPos] && (string[stringPos] == delim || string[stringPos] <= ' '))
        {
            stringPos++;
        }
        paramPos++;
    }
    do
    {
        if ((delim = format[formatPos++]) > ' ')
        {
            if (delim == '\'')
            {
                while ((delim = format[formatPos++]) && delim != '\'') {}
            }
            else if (delim != 'z')
            {
                return delim;
            }
        }
    }
    while (delim > ' ');
    return 0;
}

[felipex]

When I tried with 128 didn't compile, but with 256 it did, but when I put /setwantedlevel id level give unknown command lols

[Kar]

use mine.

pawn Код:

CMD:setwanted(playerid, params[])
{
    new id, level, str[128];
    if(sscanf(params, "ui", id, level)) return SendMsg(playerid, RED, "*USAGE: /Setwanted [playerid / part of name] [WantedLevel]");
    else if(!IsPlayerConnected(id)) return SendClientMessage(playerid, 0xFF00AAFF, "*ERROR: Player is not connected!");
    else if(id == INVALID_PLAYER_ID) return SendMsg(playerid, RED, "*Error: Invalid PlayerID");
    else if(level > 6)return SendClientMessage(playerid, red, "ERROR: Invalid Wanted Level! (0-6)");
    else
    {
        format(pfile, sizeof(pfile), pfile_path, Playername(playerid));
        if(dini_Int(pfile, "AdminLevel") >= 1 || IsPlayerAdmin(playerid))
        {
            if(IsLogged[playerid] == 0) return SendMsg(playerid, RED,"*ERROR: You Are Not Logged In Please Log In Using /Login [password]");
            {
                SetPlayerWantedLevel(playerid, level);
                format(str, sizeof(str), "*ADMIN: Administrator %s has set your WantedLevel to %i", Playername(id), level);
                SendMsg(id, BLUE, str);
                format(str, sizeof(str), "*ADMIN: You have set %s's Wantedlevel to %i", Playername(playerid), level);
                SendMsg(playerid, YELLOW, str);
            }
        }
    }
    return 1;
}

change my admin thing to yours

[felipex]

rofl arbash, what a big code, o.o