[iKarim]

drift-detection.inc: v1.0.1

This include provide basic drift detection functionality that can be used in any drift script, it doesn't require a plugin, just plug and start using it. It's aimed to be basic to avoid performance issues since it's written in PAWN. I have noticed that the drift plugin was removed from the forum (and it didn't work with newer SA-MP versions) so I decided to rewrite this include I've created a while ago and release it. I am willing to continue developing this include if it gains interest, so don't hesitate to suggest a feature or report a bug!

Preview:

Documentation:

Functions:

PHP код:

Drift::EnableDetection(playerid = -1);
Drift::EnableDamageCheck(playerid = -1);
Drift::DisableDetection(playerid = -1);
Drift::DisableDamageCheck(playerid = -1);
bool: Drift::IsDetectionEnabled(playerid = -1);
bool: Drift::IsDamageCheckEnabled(playerid = -1);
bool: Drift::IsPlayerDrifting(playerid);
Drift::SetMinAngle(Float: angle);
Drift::SetMinSpeed(Float: speed);
Drift::SetTimeoutTicks(ticks);
Float: Drift::GetMinAngle();
Float: Drift::GetMinSpeed();
Drift::GetTimeoutTicks(); 


Callbacks:

PHP код:

forward OnPlayerDriftStart(playerid);
forward OnPlayerDriftUpdate(playerid, Float: drift_angle, Float: speed);
forward OnPlayerDriftEnd(playerid, reason, Float: distance, time); 


End reasons:

• DRIFT_END_REASON_DAMAGED: vehicle is damaged (only when DamageCheck is enabled)
• DRIFT_END_REASON_TIMEOUT: player has stopped drifting for N * delay interval.
• DRIFT_END_REASON_OTHER: player left his vehicle or disconencted from the server.

Installation:

sampctl:

Код:

sampctl package install ltkarim/drift-detection

GitHub:

https://github.com/ltkarim/drift-detection

[rfr]

very nice

[RogueDrifter]

lol why re-create the thread with the same include? Simply reposting to bump?

[iKarim]

Quote:

Originally Posted by RogueDrifter lol why re-create the thread with the same include? Simply reposting to bump?

Link me to the old one please? There isn't any old threads that I could "bump".

[RogueDrifter]

You deleted it lmao, you seriously gonna deny that?
What did you even update? I see no changes from the older thread that was about a year ago.

[iKarim]

Quote:

Originally Posted by RogueDrifter You deleted it lmao, you seriously gonna deny that? What did you even update? I see no changes from the older thread that was about a year ago.

This is an entire different include, the old one was released in 2016 which was poorly written and I don't want to support it anymore, thus a new thread.

Changes:

drift-detection.inc:

PHP код:

public OnPlayerUpdate(playerid)
{
    if(g_DriftFlags & DRIFT_CHECK_ENABLED && g_DriftPlayers[playerid][playerFlags] & DRIFT_CHECK_ENABLED)
    {
        if(GetTickCount() > g_DriftPlayers[playerid][lastTimestamp])
        {
            new vehicleID = GetPlayerVehicleID(playerid);
            if(vehicleID && GetPlayerState(playerid) == PLAYER_STATE_DRIVER && IsModelACar(GetVehicleModel(vehicleID)))
            {
                new Float: vX, Float: vY, Float: vZ;
                GetVehicleVelocity(vehicleID, vX, vY, vZ);
                new Float: angle;
                GetVehicleZAngle(vehicleID, angle);
                new Float: speed;
                speed = floatsqroot(vX*vX + vY*vY + vZ*vZ) * 180.0;
                
                new Float: direction;
                direction = atan2(vY, vX);
                direction -= 90.0;
        
                if(direction < 0) direction += 360.0;
                new Float: driftAngle;
                driftAngle = angle - floatabs(direction);
                if(driftAngle > 270.0) driftAngle -= 270.0;
                if(driftAngle < -270.0) driftAngle += 270.0;
                driftAngle = floatabs(driftAngle);
            
                switch(g_DriftPlayers[playerid][driftState])
                {
                    case DRIFT_STATE_NONE:
                    {
                        if(MIN_DRIFT_ANGLE <= driftAngle <= MAX_DRIFT_ANGLE && speed >= MIN_DRIFT_SPEED)
                        {                        
                            g_DriftPlayers[playerid][driftState] = DRIFT_STATE_DRIFTING;
                            g_DriftPlayers[playerid][startTimestamp] = GetTickCount();
                            GetVehicleHealth(vehicleID, g_DriftPlayers[playerid][vHealth]);
                            GetPlayerPos(playerid, g_DriftPlayers[playerid][startPosX], g_DriftPlayers[playerid][startPosY], g_DriftPlayers[playerid][startPosZ]);
                            
                            #if defined OnPlayerDriftStart
                                OnPlayerDriftStart(playerid);
                            #endif
                        }
                    }
                    case DRIFT_STATE_DRIFTING:
                    {
                        if(g_DriftFlags & DAMAGE_CHECK_ENABLED && g_DriftPlayers[playerid][playerFlags] & DAMAGE_CHECK_ENABLED)
                        {
                            new Float: vehicleHealth;
                            GetVehicleHealth(vehicleID, vehicleHealth);
                            if(vehicleHealth < g_DriftPlayers[playerid][vHealth])
                            {
                                GetPlayerPos(playerid, vX, vY, vZ);
                                g_DriftPlayers[playerid][driftState] = DRIFT_STATE_NONE;
                                g_DriftPlayers[playerid][timeoutTicks] = 0;
                                #if defined OnPlayerDriftEnd
                                    new Float: distance;
                                    distance = GetPlayerDistanceFromPoint(playerid, g_DriftPlayers[playerid][startPosX], g_DriftPlayers[playerid][startPosY], g_DriftPlayers[playerid][startPosZ]);
                                    OnPlayerDriftEnd(playerid, DRIFT_END_REASON_DAMAGED, distance, GetTickCount() - g_DriftPlayers[playerid][startTimestamp]);
                                #endif
                            }
                        }
                        else if(MIN_DRIFT_ANGLE <= driftAngle <= MAX_DRIFT_ANGLE && speed >= MIN_DRIFT_SPEED)
                        {
                            g_DriftPlayers[playerid][timeoutTicks] = 0;
                            
                            #if defined OnPlayerDriftUpdate
                                OnPlayerDriftUpdate(playerid, driftAngle, speed);
                            #endif
                        }
                        else
                        {
                            g_DriftPlayers[playerid][timeoutTicks]++;
                            if(g_DriftPlayers[playerid][timeoutTicks] >= DRIFT_TIMEOUT_INTERVAL)
                            {
                                GetPlayerPos(playerid, vX, vY, vZ);
                                
                                g_DriftPlayers[playerid][driftState] = DRIFT_STATE_NONE;
                                g_DriftPlayers[playerid][timeoutTicks] = 0;
                                #if defined OnPlayerDriftEnd
                                    new Float: distance;
                                    distance = GetPlayerDistanceFromPoint(playerid, g_DriftPlayers[playerid][startPosX], g_DriftPlayers[playerid][startPosY], g_DriftPlayers[playerid][startPosZ]);
                                    OnPlayerDriftEnd(playerid, DRIFT_END_REASON_TIMEOUT, distance, GetTickCount() - g_DriftPlayers[playerid][startTimestamp]);
                                #endif
                            }
                        }
                    }
                }
            }
            g_DriftPlayers[playerid][lastTimestamp] = GetTickCount() + DRIFT_PROCESS_INTERVAL;
        }
    }
    #if defined Drift_OnPlayerUpdate
        return Drift_OnPlayerUpdate(playerid);
    #else
        return true;
    #endif
} 


drift.inc: (2016)

PHP код:

public OnPlayerUpdate(playerid) {
    if(GetTickCount() > P_DATA[playerid][T_TICK])
    {
        new vehicleid;
        if( (vehicleid = GetPlayerVehicleID(playerid)) && GetPlayerState(playerid) == PLAYER_STATE_DRIVER )
        {
            if(__IsModelACar(GetVehicleModel(vehicleid)))
            {
                new Float:x, Float:y, Float:z, Float:a, Float:d, Float:s, Float:drift_angle;
                GetVehicleVelocity(vehicleid, x, y, z);
                GetVehicleZAngle(vehicleid, a);
                s = floatround(floatsqroot( x*x + y*y + z*z) * 180);
                d = atan2(y, x);
                d = floatsub(d, 90.0);
                if(d < 0.0) d = floatadd(d, 360.0);
                drift_angle = a - d;
                if(drift_angle > 270.0) drift_angle -= 270.0;
                if(drift_angle < -270.0) drift_angle += 270.0;
                drift_angle = floatabs(drift_angle);
                switch (P_DATA[playerid][P_DRIFTING])
                {
                    case 0:
                    {
                        if(MIN_DRIFT_ANGLE <= drift_angle <= MAX_DRIFT_ANGLE && s >= MIN_DRIFT_SPEED && !__IsVehicleDrivingBackwards(x, y, a))
                        {
                            P_DATA[playerid][P_DRIFTING] = true;
                            P_DATA[playerid][D_STARTTICK] = GetTickCount();
                            GetVehicleHealth(vehicleid, P_DATA[playerid][V_HEALTH]);
                            GetPlayerPos(playerid, P_DATA[playerid][P_STARTX], P_DATA[playerid][P_STARTY], x);
                            CallLocalFunction("OnDriftStart", "i", playerid);
                        }
                    }
                    case 1:
                    {
                        new Float:vhealth, Float:_x, Float:_y, Float:_z;
                        GetVehicleHealth(vehicleid, vhealth);
                        GetPlayerPos(playerid, _x, _y, _z);
                        if(vhealth < P_DATA[playerid][V_HEALTH]) 
                        {
                            CallLocalFunction("OnDriftEnd", "iifi", playerid, DRIFT_END_REASON_CRASH, __GetPointDistanceToPoint(P_DATA[playerid][P_STARTX],  P_DATA[playerid][P_STARTY], _x, _y),  GetTickCount() - P_DATA[playerid][D_STARTTICK]);
                            P_DATA[playerid] = R_DATA;
                        }
                        else if(__IsVehicleDrivingBackwards(x, y, a) || s < MIN_DRIFT_SPEED)
                        {
                            CallLocalFunction("OnDriftEnd", "iifi", playerid, DRIFT_END_REASON_OTHER, __GetPointDistanceToPoint(P_DATA[playerid][P_STARTX],  P_DATA[playerid][P_STARTY], _x, _y),  GetTickCount() - P_DATA[playerid][D_STARTTICK]);
                            P_DATA[playerid] = R_DATA;
                        }
                        else if(MIN_DRIFT_ANGLE <= drift_angle <= MAX_DRIFT_ANGLE && s >= MIN_DRIFT_SPEED)
                        {
                            P_DATA[playerid][T_TIMEOUT] = 0;
                            CallLocalFunction("OnDriftUpdate", "iff", playerid, drift_angle, s);
                        }
                        else 
                        {
                            P_DATA[playerid][T_TIMEOUT]++;
                            if(P_DATA[playerid][T_TIMEOUT] >= DRIFT_TIMEOUT_INTERVAL)
                            {
                                CallLocalFunction("OnDriftEnd", "iifi", playerid, DRIFT_END_REASON_TIMEOUT, __GetPointDistanceToPoint(P_DATA[playerid][P_STARTX],  P_DATA[playerid][P_STARTY], _x, _y),  GetTickCount() - P_DATA[playerid][D_STARTTICK]);
                                P_DATA[playerid] = R_DATA;
                            }
                        }
                    }
                }
            }
        }
        P_DATA[playerid][T_TICK] = GetTickCount() + PROCESS_INTERVAL;
    }
    #if defined D_OnPlayerUpdate
        return D_OnPlayerUpdate(playerid);
    #else
        return true;
    #endif
} 


[RogueDrifter]

That's not how you go around releasing things, this is nothing different, it's literally the same include (drift based concept) you're supposed to update and notify not simply delete and recreate, that's how you fuck up the old users, you're also supposed to take people's opinions and criticizes instead of just accusing me of increasing post count simply for commenting my opinion on a release which i have the right to do whenever i feel like it.
Anyhow i'm gonna test this and see how it goes then report back here.

EDIT: it won't even compile: error 021: symbol already defined: "OnPlayerStateChange"

You missed an 'e' on line 324

[iKarim]

Quote:

Originally Posted by RogueDrifter That's not how you go around releasing things, this is nothing different, it's literally the same include (drift based concept) you're supposed to update and notify not simply delete and recreate

I didn't delete the thread just to create this thread, it was deleted way before I even think of re-releasing this include.

Quote:

Originally Posted by RogueDrifter EDIT: you forgot to hook OnPlayerStateChange

It is hooked.

[RogueDrifter]

It's not hooked right, you missed an 'e' on line 324

it's : OnPlayerStateChang

when it's supposed to be OnPlayerStateChange

[iKarim]

Quote:

Originally Posted by RogueDrifter It's not hooked right, you missed an 'e' on line 324 it's : OnPlayerStateChang when it's supposed to be OnPlayerStateChange

Fixed, thank you.

[RogueDrifter]

You're welcome, i also just tried using it, had 0 luck getting any response,
i used this:

PHP код:

public OnPlayerDriftStart(playerid)
{
    SendClientMessageToAll(-1, "Started");
    return 1;
}

public OnPlayerDriftUpdate(playerid, Float: drift_angle, Float: speed)
{
    SendClientMessageToAll(-1, "Doing");
    return 1;
}

public OnPlayerDriftEnd(playerid, reason, Float: distance, time)
{
    SendClientMessageToAll(-1, "Ended");
    return 1;
} 


and kept swinging my elegy all over the place and got 0 msgs, can you test it and upload a video? i need to see how you exactly detect drifting because i tried steerlocking, power sliding and long turns/short turns got nothing.

[iKarim]

Quote:

Originally Posted by RogueDrifter You're welcome, i also just tried using it, had 0 luck getting any response, i used this: PHP код: public OnPlayerDriftStart(playerid) {     SendClientMessageToAll(-1, "Started");     return 1; } public OnPlayerDriftUpdate(playerid, Float: drift_angle, Float: speed) {     SendClientMessageToAll(-1, "Doing");     return 1; } public OnPlayerDriftEnd(playerid, reason, Float: distance, time) {     SendClientMessageToAll(-1, "Ended");     return 1; }  and kept swinging my elegy all over the place and got 0 msgs, can you test it and upload a video? i need to see how you exactly detect drifting because i tried steerlocking, power sliding and long turns/short turns got nothing.

https://gfycat.com/gifs/detail/Refle...lligatorlizard

You need to enable drift globally and per player first. Check test.pwn. The include itself is disabled by default, you have to call Drift::EnableDetection();
in script init and Drift::EnableDetection(playerid) to enable detection for the player.

[RogueDrifter]

Okay it does work, i got some things to report tho, first of all the detection is too sensitive if i make a simple turn without turning my nos on it's detecting me drifting i can go all over the map with this without calling the drift end function so i SUGGEST 3 things,
1- make min speed 50.0 by default
2- make the angle detection sharper (smaller angle the car must turn more but not too much)
3- decrease the time of detection between each drift end.
And the damage detection won't work for me, i used damagecheckenable globally and per-player and it still wont work it keeps saying drift end reason 0

I can give you tips on this, it was hard for me to detect when i first started working on my drift system so if you can't get it to work, you basically get the vehicle's health the moment a player starts drifting, then when he's in the update-drift stage you keep checking for the vehicle's health if < when he started = drift end reason damage AND update the original car's health variable to the current vehicle's health. Also don't forget to update it every time SetVehicleHealth is used so you'll need to make this work for both filterscripts and gamemodes using #if defined FILTERSCRIPT and #else at the beginning and end and tell the users to include it in filterscripts and gamemodes and only edit through the gamemode.

[iKarim]

1-2. I am planning to create global functions to set the minimum angle & speed to initiate the drift so it could be adjusted per user needs, as well as increase the defaults in the next update.

3. Same goes for this, however I think it should be defaulted like that, but it'll be adjustable globally.

The damage detection worked for me flawlessy (although I have had to get another player to shoot my car), and this is exactly the same method you suggested, except for the SetVehicleHeath which will be hooked in the next update.

Thank you for your feedback.

[RogueDrifter]

It won't work at all for me, i kept banging the car against walls it wouldn't end for damage reason, try it now, it only ends if someone shoots the car? shouldn't be whenever the car is damaged?

[iKarim]

Quote:

Originally Posted by RogueDrifter It won't work at all for me, i kept banging the car against walls it wouldn't end for damage reason, try it now, it only ends if someone shoots the car? shouldn't be whenever the car is damaged?

I'll have a look again, but it should work either way:

PHP код:

if(g_DriftFlags & DAMAGE_CHECK_ENABLED && g_DriftPlayers[playerid][playerFlags] & DAMAGE_CHECK_ENABLED)
{
    new Float: vehicleHealth;
    GetVehicleHealth(vehicleID, vehicleHealth);
    if(vehicleHealth < g_DriftPlayers[playerid][vHealth])
    {
        GetPlayerPos(playerid, vX, vY, vZ);
        g_DriftPlayers[playerid][driftState] = DRIFT_STATE_NONE;
        g_DriftPlayers[playerid][timeoutTicks] = 0;
        #if defined OnPlayerDriftEnd
            new Float: distance;
            distance = GetPlayerDistanceFromPoint(playerid, g_DriftPlayers[playerid][startPosX], g_DriftPlayers[playerid][startPosY], g_DriftPlayers[playerid][startPosZ]);
            OnPlayerDriftEnd(playerid, DRIFT_END_REASON_DAMAGED, distance, GetTickCount() - g_DriftPlayers[playerid][startTimestamp]);
        #endif
    }
} 


[RogueDrifter]

Quote:

Originally Posted by iKarim I'll have a look again, but it should work either way: PHP код: if(g_DriftFlags & DAMAGE_CHECK_ENABLED && g_DriftPlayers[playerid][playerFlags] & DAMAGE_CHECK_ENABLED) {     new Float: vehicleHealth;     GetVehicleHealth(vehicleID, vehicleHealth);     if(vehicleHealth < g_DriftPlayers[playerid][vHealth])     {         GetPlayerPos(playerid, vX, vY, vZ);         g_DriftPlayers[playerid][driftState] = DRIFT_STATE_NONE;         g_DriftPlayers[playerid][timeoutTicks] = 0;         #if defined OnPlayerDriftEnd             new Float: distance;             distance = GetPlayerDistanceFromPoint(playerid, g_DriftPlayers[playerid][startPosX], g_DriftPlayers[playerid][startPosY], g_DriftPlayers[playerid][startPosZ]);             OnPlayerDriftEnd(playerid, DRIFT_END_REASON_DAMAGED, distance, GetTickCount() - g_DriftPlayers[playerid][startTimestamp]);         #endif     } }

I looked at your code but it's too bad to not hook setvehiclehealth the way i told you but good job overall with the tips i provided it would be pretty cool and i would use it for my own, i might fork it on github to help out with the vehicle health damage check thing, good luck.

[iKarim]

Update v1.1.0

New functions:

PHP код:

stock Drift::SetMinAngle(Float: angle);
stock Drift::SetMinSpeed(Float: speed);
stock Drift::SetTimeoutTicks(ticks);
stock Float: Drift::GetMinAngle();
stock Float: Drift::GetMinSpeed();
stock Drift::GetTimeoutTicks(); 


Changes:

• Drift detection and vehicle damage checks are enabled globally by default.
• Increased default drift angle and speed to initiate a drift

Download:

Github: https://github.com/ltkarim/drift-detection/releases

[RogueDrifter]

Good job I like the new default settings, did you fix the damage check thing? Made sure it works?

[iKarim]

Quote:

Originally Posted by RogueDrifter Good job I like the new default settings, did you fix the damage check thing? Made sure it works?

Thanks, and yes. It should be working fine now.