[En2katas]

I should state that this team would zcmd

pawn Код:

if(!strcmp(cmdtext, "/rep",true,5))
    {
        if(!playerDB[playerid][repka])
        {
            if(!cmdtext[4])
            {
                SendClientMessage(playerid,Melina,"* Uždeti viena reputacijos tašką žaidėjui: /rep [Vardas_Pavardė] [Už ką]");
                return 1;
            }
            new name[24],vardas[24],repuzka[256];
            strmid(name,GetArgument(1, cmdtext,0),0,MAX_PLAYER_NAME);
            repuzka = GetArgument(2, cmdtext,1);
            if(!strcmp(name, "0", true) || !strcmp(repuzka, "0", true)) {SendClientMessage(playerid, BLUE, "Uždeti viena reputacijos tašką žaidėjui: /rep [Dalis_Vardo] [Už ką]"); return 1;}
            new id = GetPlayeridMid(name);
            if(id == INVALID_PLAYER_ID){SendClientMessage(playerid,BLUE,"* Žaidėjo su tokiu vardų nėra!"); return 1;}
            if (id == playerid){ SendClientMessage(playerid, RED, "* Sau reputacijos taškų negali duoti!"); return 1;}
            GetPlayerName(id,name,sizeof(name));
            GetPlayerName(playerid,vardas,sizeof(vardas));
            playerDB[id][reputacija]++;
            new rep = playerDB[id][reputacija];
            new msg1[120],msg2[120],msg3[130],msg4[80];
            format(msg1,sizeof(msg1),"* Žaidėjui %s uždėjote viena reputacijos tašką, už {FFFFFF}%s",name,repuzka);
            SendClientMessage(playerid,BLUE,msg1);
            format(msg2,sizeof(msg2),"* Žaidėjas %s jums uždėjo viena reputacijos tašką, už {FFFFFF}%s.",vardas,repuzka);
            SendClientMessage(id,BLUE,msg2);
            format(msg3,sizeof(msg3),"* Dabar jūs turite %i reputacijos tašką (-us)!",rep);
            SendClientMessage(id,BLUE,msg3);
            if(playerDB[id][reputacija]==50)
            {
                SendClientMessage(id,Zalia,"{FFFFFF}* Sveikiname, jūs surinkote {FF0000}50 {FFFFFF}reputacijos taškų!");
                SendClientMessage(id,Zalia,"{FFFFFF}* Už tai gaunate dovanų!");
                GivePlayerMoneyA(playerid, 1000);
                SetPlayerScore(playerid,GetPlayerScore(playerid)+100);
                format(msg4,sizeof(msg4),"{FFFFFF}* Žaidejas {FF0000}%s {FFFFFF}surinko 50 reputacijos taškų. Tad galite jo klausti, jis jums tikrai padės",name);
                SendClientMessageToAll(BLUE,msg4);
            }
            playerDB[playerid][repka] = true;
            SetTimerEx("reptimer", 60000*1, 0, "i", playerid);
        }
        else
        {
            SendClientMessage(playerid, RED, "* Reputaciją galima duoti kas 1 minutę!");
        }
        return 1;
    }

[xVIP3Rx]

I don't understand what's the problem or what do you need help with..
Also use [Pawn] instead of [spoiler]

[En2katas]

Uped

[saratchandra]

EDITED!!

[xVIP3Rx]

Quote:

Originally Posted by En2katas Uped

Quote:

Originally Posted by xVIP3Rx I don't understand what's the problem or what do you need help with..

Can you explain what do you need in this code ?

[En2katas]

I need that there is zcmd team: CMD:rep(playerid, params[])...

[Konstantinos]

It was too difficult to understand what was what because of the non-English language but I guess I got it right.

Use ZCMD with sscanf.

pawn Код:

CMD:rep(playerid, params[])
{
    if(playerDB[playerid][repka]) return SendClientMessage(playerid, RED, "* Reputaciją galima duoti kas 1 minutę!");
    new id, reason[100];
    if(sscanf(params, "rs[100]", id, reason)) return SendClientMessage(playerid,Melina,"* Uћdeti viena reputacijos taљką ћaidėjui: /rep [Vardas_Pavardė] [Uћ ką]");
    if(id == INVALID_PLAYER_ID) return SendClientMessage(playerid,BLUE,"* Ћaidėjo su tokiu vardų nėra!");
    if(id == playerid) return SendClientMessage(playerid, RED, "* Sau reputacijos taљkų negali duoti!");
    new name[MAX_PLAYER_NAME], vardas[MAX_PLAYER_NAME], msg1[128];
    GetPlayerName(id,name,MAX_PLAYER_NAME);
    GetPlayerName(playerid,vardas,MAX_PLAYER_NAME);
    playerDB[id][reputacija]++;
    format(msg1,sizeof(msg1),"* Ћaidėjui %s uћdėjote viena reputacijos taљką, uћ {FFFFFF}%s",name,reason);
    SendClientMessage(playerid,BLUE,msg1);
    format(msg1,sizeof(msg1),"* Ћaidėjas %s jums uћdėjo viena reputacijos taљką, uћ {FFFFFF}%s.",vardas,reason);
    SendClientMessage(id,BLUE,msg1);
    format(msg1,sizeof(msg1),"* Dabar jūs turite %i reputacijos taљką (-us)!",playerDB[id][reputacija]);
    SendClientMessage(id,BLUE,msg1);
    if(playerDB[id][reputacija]==50)
    {
        SendClientMessage(id,Zalia,"{FFFFFF}* Sveikiname, jūs surinkote {FF0000}50 {FFFFFF}reputacijos taљkų!");
        SendClientMessage(id,Zalia,"{FFFFFF}* Uћ tai gaunate dovanų!");
        GivePlayerMoneyA(playerid, 1000);
        SetPlayerScore(playerid,GetPlayerScore(playerid)+100);
        format(msg1,sizeof(msg1),"{FFFFFF}* Ћaidejas {FF0000}%s {FFFFFF}surinko 50 reputacijos taљkų. Tad galite jo klausti, jis jums tikrai padės",name);
        SendClientMessageToAll(BLUE,msg1);
    }
    playerDB[playerid][repka] = true;
    SetTimerEx("reptimer", 60000*1, 0, "i", playerid);
    return 1;
}

[En2katas]

thank you