[Kaliber]

Nah i am sry...

It is a little bit more complex the problem

Okay here the new fix:

PHP код:

/* Sa-Mp Include Fix
 *
 * © by Kaliber, 2015
 *
 */
/******************************************************************************/
#if !defined _samp_included
    #include <a_samp>
#endif
/******************************************************************************/
#if defined _samp_fix
    #endinput
#endif
#define _samp_fix
/******************************************************************************/
native __fopen(name[], filemode:mode = io_readwrite) = fopen;
native __fread(File:handle, string[], size = sizeof string, bool: pack = false) = fread;
native __fclose(File:handle) = fclose;
/******************************************************************************/
stock File:_fopen(name[], filemode:mode = io_readwrite) {
    const File:error = File:-1;
    return (!fexist(name)) ? error : File:__fopen(name,mode);
}
/******************************************************************************/
#if defined _ALS_fopen
    #undef fopen
#else
    #define _ALS_fopen
#endif
#define fopen _fopen
/******************************************************************************/
stock _fread(File:handle, string[], size = sizeof string, bool: pack = false)
    return (handle == File:-1) ? 0 : __fread(handle,string,size,pack);
/******************************************************************************/
#if defined _ALS_fread
    #undef fread
#else
    #define _ALS_fread
#endif
#define fread _fread
/******************************************************************************/
stock _fclose(File:handle)
    return (handle == File:-1) ? 0 : __fclose(handle);
/******************************************************************************/
#if defined _ALS_fclose
    #undef fclose
#else
    #define _ALS_fclose
#endif
#define fclose _fclose
/******************************************************************************/