[SmiT]

Here is an example:

pawn Код:

#include <a_samp>
#include <YSI\y_ini>

enum PLAYER_ENUM
{
    pScore
}
new pVar[ MAX_PLAYERS ][ PLAYER_ENUM ];


forward load_user_score(playerid,name[],value[]);
public load_user_score(playerid,name[],value[])
{
    INI_Int("Score", pVar[ playerid ][ pScore ]);
    return true;
}

stock USER_PATH(playerid)
{
    new 
        _str[ 128 ],P_NAME[ MAX_PLAYER_NAME ];
        
    GetPlayerName( playerid, P_NAME, MAX_PLAYER_NAME );
    format( _str, sizeof ( _str ), "%s.ini", P_NAME );
    return _str;
}

public OnPlayerConnect( playerid )
{
    pVar[ playerid ][ pScore ] = 0;
    INI_ParseFile( USER_PATH ( playerid ), "load_user_%s", .bExtra = true, .extra = playerid );
    SetPlayerScore( playerid, pVar[ playerid ][ pScore ] );
    return true;
}

public OnPlayerDisconnect( playerid, reason )
{
    new INI:File = INI_Open( USER_PATH ( playerid ));
    INI_SetTag(File,"score");
    INI_WriteInt(File,"Score", GetPlayerScore( playerid ));
    INI_Close(File);
    return true;
}

public OnPlayerDeath( playerid, killerid, reason )
{
    if ( killerid != INVALID_PLAYER_ID )
    {
        SetPlayerScore( killerid, GetPlayerScore( killerid ) + 1 );
    }
    return true;
}