[MoroDan]

Add this at bottom of your script:

PHP код:

ReturnUser(text[], playerid = INVALID_PLAYER_ID)
{
    new pos = 0;
    while (text[pos] < 0x21)
    {
        if (text[pos] == 0) return INVALID_PLAYER_ID;
        pos++;
    }
    new userid = INVALID_PLAYER_ID;
    if (IsNumeric(text[pos])) // Check whole passed string
    {
        userid = strval(text[pos]);
        if (userid >= 0 && userid < MAX_PLAYERS)
        {
            if(!IsPlayerConnected(userid))
            {
                userid = INVALID_PLAYER_ID;
            }
            else
            {
                return userid; // A player was found
            }
        }
    }
    // They entered [part of] a name or the id search failed (check names just incase)
    new len = strlen(text[pos]);
    new count = 0;
    new name[MAX_PLAYER_NAME];
    catch(Player, i)
    {
        GetPlayerName(i, name, sizeof (name));
        if (strcmp(name, text[pos], true, len) == 0) // Check segment of name
        {
            if (len == strlen(name)) // Exact match
            {
                return i; // Return the exact player on an exact match
                // Otherwise if there are two players:
                // Me and MeYou any time you entered Me it would find both
                // And never be able to return just Me's id
            }
            else // Partial match
            {
                count++;
                userid = i;
            }
        }
    }
    if (count != 1)
    {
        if (playerid != INVALID_PLAYER_ID)
        {
            if (count)
            {
                SendClientMessage(playerid, 0xFF0000AA, "Au fost gasiti mai multi utilizatori, te rugam sa cauti mai detaliat");
            }
            else
            {
                SendClientMessage(playerid, 0xFF0000AA, "Nu a fost gasit un utilizator potrivit");
            }
        }
        userid = INVALID_PLAYER_ID;
    }
    return userid; // INVALID_USER_ID for bad return
}