[Basicz]

Quote:

Originally Posted by WoodPecker Add this at OnPlayerCommandText: new sendername[MAX_PLAYER_NAME]; new cmd[128]; cmd = strtok(cmdtext, idx);

Why STRTOK?

For a /report command, here it is.

Requirements :

ZCMD

SSCANF2

pawn Код:

stock pName( playerid ) { 
    new b[ 24 ]; 
    return GetPlayerName( playerid, b, 24 ), b;
}

COMMAND:report( playerid, params[ ] )
{
    new
        userid,
        reason[ 64 ]
    ;

    if ( sscanf( params, "us[64]", userid, reason ) )
       return SendClientMessage( playerid, -1, "{FFDD00}/Report < PartOfName/ID > < Reason >" );

    if ( userid == playerid )
        return SendClientMessage( playerid, -1, "{FFDD00}You cannot report yourself." );

    if ( userid == INVALID_PLAYER_ID )
        return SendClientMessage( playerid, -1, "{FFDD00}Invalid player." );

    SendClientMessage( playerid, -1, "{FFDD00}Report has been sent to the online RCON administrators." );

    for ( new j = GetMaxPlayers( ), i; i < j; i ++ )
    {
        if ( !IsPlayerConnected( i ) )
            continue;

        if ( IsPlayerAdmin( i ) )
        {
            new
                szReportString[ 128 ]
            ;

            format( szReportString, sizeof szReportString, "Report from %s: %s(%d) = %s.",
                pName( playerid ), pName( userid ), userid, reason );

            SendClientMessage( i, 0xAA0000AA, szReportString );
        }
    }

    return 1;
}

Use BASE.PWN ( Filterscript, included in the default server folder ) for /kick, /ban, /pm commands.