[smeti]

Quote:

Originally Posted by RyDeR` pawn Код: stock UpdateVehicleParamsEx(vehicleid, bool: status, { _, Float }: ...) {     new         vehicleParams[7],         vehicleParamsData[7][10] =         {             { "Engine" },             { "Lights" },             { "Alarm" },             { "Doors" },             { "Bonnet" },             { "Boot" },             { "Objective" }         },         totalArgs = numargs()     ;     if(totalArgs < 3)     {         return 0;     }     GetVehicleParamsEx(vehicleid, vehicleParams[0], vehicleParams[1], vehicleParams[2], vehicleParams[3], vehicleParams[4], vehicleParams[5], vehicleParams[6]);     for(new i = 2, j = 0, ch = '\0'; i != totalArgs; ++i)     {         new             tempString[10]         ;         for(j = 0; (ch = getarg(i, j)) != EOS; ++j)         {             tempString[j] = ch;         }         for(j = 0; j != sizeof(vehicleParamsData); ++j)         {             if(!strcmp(vehicleParamsData[j], tempString, true))             {                 vehicleParams[j] = status;             }         }     }     SetVehicleParamsEx(vehicleid, vehicleParams[0], vehicleParams[1], vehicleParams[2], vehicleParams[3], vehicleParams[4], vehicleParams[5], vehicleParams[6]);     return 1; } Examples: pawn Код: UpdateVehicleParamsEx(vehicleid, true, "Engine", "Boot", "Doors"); will start engine, open boot and doors. or pawn Код: UpdateVehicleParamsEx(vehicleid, true, "Alarm", "Bonnet", "Doors", "Boot", "Engine"); will start the alarm, open bonnet, doors, boot and engine. Notice: true is for ON and false is for OFF.

Grat.
The same little differently:

pawn Код:

enum 
    Params_type
{
    Engine,
    Lights,
    Alarm,
    Doors,
    Bonnet,
    Boot,
    Objective
};

Modified verzion 1:

pawn Код:

stock UpdateVehicleParamsEx(vehicleid, status, {Params_type}:...)
{
    new
        v_Params[7],
    argpos = numargs() - 2;  // vehicleid and status = 2 arguments

    GetVehicleParamsEx(vehicleid, v_Params[0], v_Params[1], v_Params[2], v_Params[3], v_Params[4], v_Params[5], v_Params[6]);
    while(argpos--)
    {
        switch(Params_type:getarg(argpos+2))
        {
            case Engine: v_Params[0] = status;
            case Lights: v_Params[1] = status;
            case Alarm: v_Params[2] = status;
            case Doors: v_Params[3] = status;
            case Bonnet: v_Params[4] = status;
            case Boot: v_Params[5] = status;
            case Objective: v_Params[6] = status;
        }
    }
    SetVehicleParamsEx(vehicleid, v_Params[0], v_Params[1], v_Params[2], v_Params[3], v_Params[4], v_Params[5], v_Params[6]);    
    return 1;
}

Modified verzion 2:

pawn Код:

stock 
    UpdateVehicleParamsEx(vehicleid, status, {Params_type}:...)
{
    new
        v_Params[7],
        argpos = numargs() - 2;  // vehicleid and status = 2 arguments
    GetVehicleParamsEx(vehicleid, v_Params[0], v_Params[1], v_Params[2], v_Params[3], v_Params[4], v_Params[5], v_Params[6]);
    while(argpos--)
        v_Params[getarg(argpos+2)] = status;
    SetVehicleParamsEx(vehicleid, v_Params[0], v_Params[1], v_Params[2], v_Params[3], v_Params[4], v_Params[5], v_Params[6]);    
    return 1;
}

Test command:

pawn Код:

COMMAND:testparams(playerid, params[])
{
    new
        vehicleid = GetPlayerVehicleID(playerid);
    if(vehicleid)
        UpdateVehicleParamsEx(vehicleid, VEHICLE_PARAMS_ON, Lights, Boot, Bonnet);
    return 1;
}