[Shram]

Хай
Имеется 3D текст и массив с авто, хочу прикрепить к ним 3Д текст, делаю таким образом:
Авто загружаются нормально и 3Д текст появляется на 0.0.0 координатах, но почему к транспорту не аттачиться. В чём может быть проблема?
Предполагаю, что может быть проблема в Attach3DTextLabel?

PHP Code:

new Text3D:Buss; 
    Buss = Create3DTextLabel( "ТЕСТ", 0xFF0000AA, 7.77, 7.77, 7.77, 100.0, 0, 1 ); 
    for (new i=0;i<sizeof(VehicleBussSpawns);i++) 
    { 
        if (VehicleBussSpawns[i][vspawn_model] != 0) 
        { 
            AddVehicleSpawn(VehicleBussSpawns[i][vspawn_model],VehicleBussSpawns[i][vspawn_x],VehicleBussSpawns[i][vspawn_y],VehicleBussSpawns[i][vspawn_z],VehicleBussSpawns[i][vspawn_heading],VehicleBussSpawns[i][vspawn_colour1],VehicleBussSpawns[i][vspawn_colour2]); 
            Attach3DTextLabelToVehicle( Buss, V_RUMPO, 0.0, 0.0, 2.0 ); 
        } 
    } 


[ZiGGi]

Ты прикрепляешь к V_RUMPO, а не к только что созданному транспорту.

[S4D]

Attach3DTextLabelToVehicle( Buss, id машины, 0.0, 0.0, 2.0 );

[Shram]

Ребят, я не могу догнать что именно вписать в Attach3DTextLabelToVehicle -_-
На месте id машины не понимаю что должно быть

С этой конструкцией тоже не работает

PHP Code:

Attach3DTextLabelToVehicle( Buss, VehicleBussSpawns[i][vspawn_model], 0.0, 0.0, 2.0 ); 


[ZiGGi]

Посмотри пример на wiki.

[Shram]

Quote:

Originally Posted by ZiGGi Посмотри пример на wiki.

Получается мне нужно узнать игровой id авто ?

[stabker]

PHP Code:

for (new i=0;i<sizeof(VehicleBussSpawns);i++)  
{  
    if (VehicleBussSpawns[i][vspawn_model] != 0)  
    {  
        new vehicleid = CreateVehicle(VehicleBussSpawns[i][vspawn_model],VehicleBussSpawns[i][vspawn_x],VehicleBussSpawns[i][vspawn_y],VehicleBussSpawns[i][vspawn_z],VehicleBussSpawns[i][vspawn_heading],VehicleBussSpawns[i][vspawn_colour1],VehicleBussSpawns[i][vspawn_colour2], __ВРЕМЯ_РЕСПАВНА_В_МИЛЛИСЕКУНДАХ__);  
        //создает машину и вернет ее ид в переменную vehicleid
        
        new Text3D: textid = Create3DTextLabel( "ТЕСТ", 0xFF0000AA, 7.77, 7.77, 7.77, 100.0, 0, 1 );
        //создает 3д текст и вернет его ид в переменную textid
        
        Attach3DTextLabelToVehicle(textid, vehicleid, 0.0, 0.0, 2.0 );
        //прикрепит 3д текст, ид которого хранит переменная textid, к машине, ид которой хранится в переменной vehicleid
    }  
} 


Так понятно?

P.S. Не знаю, что за функция AddVehicleSpawn, заменил на стандартную. Ид 3д текста и ид машины нужно сохранять не локально, если они будут нужны в будущем.

[Shram]

Quote:

Originally Posted by stabker PHP Code: for (new i=0;i<sizeof(VehicleBussSpawns);i++)   {       if (VehicleBussSpawns[i][vspawn_model] != 0)       {           new vehicleid = CreateVehicle(VehicleBussSpawns[i][vspawn_model],VehicleBussSpawns[i][vspawn_x],VehicleBussSpawns[i][vspawn_y],VehicleBussSpawns[i][vspawn_z],VehicleBussSpawns[i][vspawn_heading],VehicleBussSpawns[i][vspawn_colour1],VehicleBussSpawns[i][vspawn_colour2], __ВРЕМЯ_РЕСПАВНА_В_МИЛЛИСЕКУНДАХ__);           //создает машину и вернет ее ид в переменную vehicleid                  new Text3D: textid = Create3DTextLabel( "ТЕСТ", 0xFF0000AA, 7.77, 7.77, 7.77, 100.0, 0, 1 );         //создает 3д текст и вернет его ид в переменную textid                  Attach3DTextLabelToVehicle(textid, vehicleid, 0.0, 0.0, 2.0 );         //прикрепит 3д текст, ид которого хранит переменная textid, к машине, ид которой хранится в переменной vehicleid     }   }  Так понятно? P.S. Не знаю, что за функция AddVehicleSpawn, заменил на стандартную. Ид 3д текста и ид машины нужно сохранять не локально, если они будут нужны в будущем.

Да, благодарю
Функция AddVehicleSpawn служит для добавления авто в моде, в ней заложены проверки различного рода для корректного загрузки авто.

PHP Code:

AddVehicleSpawn(Model,Float:X,Float:Y,Float:Z,Float:Heading,Colour1,Colour2) 


Но мне желательно реализовать с помощью именно этой функции

PHP Code:

new vehicleid = AddVehicleSpawn(VehicleBussSpawns[i][vspawn_model],VehicleBussSpawns[i][vspawn_x],VehicleBussSpawns[i][vspawn_y],VehicleBussSpawns[i][vspawn_z],VehicleBussSpawns[i][vspawn_heading],VehicleBussSpawns[i][vspawn_colour1],VehicleBussSpawns[i][vspawn_colour2], __ВРЕМЯ_РЕСПАВНА_В_МИЛЛИСЕКУНДАХ__); 


При компиляции выдаёт ошибку warning 209: function "AddVehicleSpawn" should return a value

[joker2020pro]

Покажите тело функции AddVehicleSpawn

[Shram]

Quote:

Originally Posted by joker2020pro Покажите тело функции AddVehicleSpawn

PHP Code:

AddVehicleSpawn(Model,Float:X,Float:Y,Float:Z,Float:Heading,Colour1,Colour2)
{
    if (Model < 400 || Model > 611)
    {
    WriteLog("Warning! Attemp to spawn unknown vehicle!");
    return ;
    }
    
    if (ActiveVehiclesCount >= MAX_VEHICLE_SPAWNS)
    {// if we already have 250 vehicles spawned, we can spawn no more, return
        
        new logstring[256];
        format(logstring, sizeof (logstring), "Warning! Vehicle limit reached. '%s' failed to spawn.",GetVehicleName(Model));
        WriteLog(logstring);
        return;
    }
    
    if ((AvtiveVehicleModelCount(Model) == 0) && (ActiveVehicleModelsCount() >= MAX_VEHICLE_MODELS))
    {//if no vehicles of that model are already spawned && over 49 models already used
    // we will change the model to a random one we have already used
        new newmodel;
        new i;
        while ((i<5)&&(AvtiveVehicleModelCount(newmodel) == 0))
        { // we will find a model we have already used
            i++;
            newmodel = GetRndVModelByLevel(16); 
        }
        if (AvtiveVehicleModelCount(newmodel)==0)
        { // if we still failed to find a useable model, return
            
            new logstring[256];
            format(logstring, sizeof (logstring), "Error: '%s' failed to load.",GetVehicleName(Model));
            WriteLog(logstring);
            return;
        }
        
        new logstring[256];
        format(logstring, sizeof (logstring), "Warning! Vehicle models limit reached. '%s' changed to '%s'.",GetVehicleName(Model),GetVehicleName(newmodel));
        WriteLog(logstring);
        Model = newmodel;
    }
    ActiveVehicles[ActiveVehiclesCount]=Model;
    ActiveVehiclesCount++;
//    CreateVehicle(Model, X,Y,Z, Heading, Colour1, Colour2, never);
    //new vehicleid=ActiveVehiclesCount-1;
    //SetVehicleNumberPlate( vehicleid, GetVehicleName(GetVehicleModel(vehicleid)) );
    AddStaticVehicleEx(Model, X,Y,Z, Heading, Colour1, Colour2, never);
    //set(SpeedVehicleName[vehicleid],GetVehicleName(GetVehicleModel(vehicleid)));
    
    new logstring[256];
    format(logstring, sizeof (logstring), "Vehicle: '%s' added to static vehicles.",GetVehicleName(Model));
    WriteLog(logstring);
} 


[joker2020pro]

PHP Code:

AddVehicleSpawn(Model,Float:X,Float:Y,Float:Z,Float:Heading,Colour1,Colour2) 
{ 
    if (Model < 400 || Model > 611) 
    { 
    WriteLog("Warning! Attemp to spawn unknown vehicle!"); 
    return INVALID_VEHICLE_ID; 
    } 
     
    if (ActiveVehiclesCount >= MAX_VEHICLE_SPAWNS) 
    {// if we already have 250 vehicles spawned, we can spawn no more, return 
         
        new logstring[256]; 
        format(logstring, sizeof (logstring), "Warning! Vehicle limit reached. '%s' failed to spawn.",GetVehicleName(Model)); 
        WriteLog(logstring); 
        return INVALID_VEHICLE_ID; 
    } 
     
    if ((AvtiveVehicleModelCount(Model) == 0) && (ActiveVehicleModelsCount() >= MAX_VEHICLE_MODELS)) 
    {//if no vehicles of that model are already spawned && over 49 models already used 
    // we will change the model to a random one we have already used 
        new newmodel; 
        new i; 
        while ((i<5)&&(AvtiveVehicleModelCount(newmodel) == 0)) 
        { // we will find a model we have already used 
            i++; 
            newmodel = GetRndVModelByLevel(16);  
        } 
        if (AvtiveVehicleModelCount(newmodel)==0) 
        { // if we still failed to find a useable model, return 
             
            new logstring[256]; 
            format(logstring, sizeof (logstring), "Error: '%s' failed to load.",GetVehicleName(Model)); 
            WriteLog(logstring); 
            return INVALID_VEHICLE_ID; 
        } 
         
        new logstring[256]; 
        format(logstring, sizeof (logstring), "Warning! Vehicle models limit reached. '%s' changed to '%s'.",GetVehicleName(Model),GetVehicleName(newmodel)); 
        WriteLog(logstring); 
        Model = newmodel; 
    } 
    ActiveVehicles[ActiveVehiclesCount]=Model; 
    ActiveVehiclesCount++; 
//    CreateVehicle(Model, X,Y,Z, Heading, Colour1, Colour2, never); 
    //new vehicleid=ActiveVehiclesCount-1; 
    //SetVehicleNumberPlate( vehicleid, GetVehicleName(GetVehicleModel(vehicleid)) ); 
    new vehicleid = CreateVehicle(Model, X,Y,Z, Heading, Colour1, Colour2, -1); 
    //set(SpeedVehicleName[vehicleid],GetVehicleName(GetVehicleModel(vehicleid))); 
    
    if(vehicleid == INVALID_VEHICLE_ID)
    {
        new logstring[256]; 
        format(logstring, sizeof (logstring), "Warning! Vehicle limit reached. '%s' failed to spawn.",GetVehicleName(Model)); 
        WriteLog(logstring); 
        return INVALID_VEHICLE_ID; 
    }
     
    new logstring[256]; 
    format(logstring, sizeof (logstring), "Vehicle: '%s' added to static vehicles.",GetVehicleName(Model)); 
    WriteLog(logstring); 
    
    return vehicleid;
}