[Immortal99]

Here Is My Code Of The Away From Keyboard System:

PHP код:

//-------------------------[Includes]-------------------------------------//
#include <a_samp>
#include <zcmd>
#define dcmd(%1,%2,%3) if (!strcmp((%3)[1], #%1, true, (%2)) && ((((%3)[(%2) + 1] == '\0') && (dcmd_%1(playerid, ""))) || (((%3)[(%2) + 1] == ' ') && (dcmd_%1(playerid, (%3)[(%2) + 2]))))) return 1
#pragma tabsize 0
//-------------------------[Color Defines]-------------------------------------//
#define COLOR_WHITE 0xFFFFFFAA
#define COLOR_GREEN 0x00FF00AA
#define COLOR_RED 0xFF0000AA
#define COLOR_LIGHTBLUE 0x33CCFFAA
#define COLOR_YELLOW 0xFFFF00AA
enum Player
{
    AFKstatus
}
new PlayerInfo[MAX_PLAYERS][Player];
public OnFilterScriptInit()
{
        print("\n--------------------------------------");
        print("Elite Gaming Away From Keyboard System Loaded!");
        print("--------------------------------------\n");
        return 1;
}
public OnFilterScriptExit()
{
        return 1;
}
dcmd_afk(playerid, params[])
        {
            #pragma unused params
                new string[256];
                if (PlayerInfo[playerid][AFKstatus] == 1)
                {
                        SendClientMessage(playerid, COLOR_RED, "SERVER:{FFFFFF} You are already /afk");
                        return 1;
                }
                else if (PlayerInfo[playerid][AFKstatus] == 0)
                {
                        new pname[MAX_PLAYER_NAME];
                        GetPlayerName(playerid, pname, sizeof(pname));
                        format(string, sizeof(string), "*{FFFFFF} %s is now AFK", pname);
                        SendClientMessageToAll(COLOR_YELLOW, string);
                        TogglePlayerControllable(playerid,0);
                        SetPlayerVirtualWorld(playerid, GetPlayerVirtualWorld(playerid) + 50);
                        PlayerInfo[playerid][AFKstatus] = 1;
                        return 1;
                }
return 0;
}
dcmd_back(playerid, params[])
{
    #pragma unused params
     new string [256];
      if (PlayerInfo[playerid][AFKstatus] == 0)
           {
             SendClientMessage(playerid, COLOR_RED, "SERVER:{FFFFFF} You aren't /afk");
               return 1;
           }
            else if (PlayerInfo[playerid][AFKstatus] == 1)
                {
                        new pname[MAX_PLAYER_NAME];
                        GetPlayerName(playerid, pname, sizeof(pname));
                        format(string, sizeof(string), "*{FFFFFF} %s is now back!", pname);
                        SendClientMessageToAll(COLOR_YELLOW, string);
                        TogglePlayerControllable(playerid,1);
                        SetPlayerVirtualWorld(playerid, GetPlayerVirtualWorld(playerid) - 50);
                        PlayerInfo[playerid][AFKstatus] = 0;
                        return 1;
}
CMD:afkhelp(playerid, params [])
{
    SendClientMessage(playerid, COLOR_RED, "____Elite Gaming Away From Keyboard Help____");
    SendClientMessage(playerid, COLOR_WHITE, "To go in AFK Status use /afk");
    SendClientMessage(playerid, COLOR_WHITE, "To get back into your normal status use /back");
    return 1;
}
return 0;
}
public OnPlayerDisconnect(playerid, reason)
{
        PlayerInfo[playerid][AFKstatus] = 0;
        return 1;
}
public OnPlayerText(playerid, text[])
{
        if (PlayerInfo[playerid][AFKstatus] == 1)
        {
                SendClientMessage(playerid, COLOR_RED, "SERVER:{FFFFFF} You need to type /back to speak");
                return 0;
        }
        else if (PlayerInfo[playerid][AFKstatus] == 0)
        {
                return 1;
        }
        return 1;
}
public OnPlayerCommandText(playerid, cmdtext[])
{
        dcmd(afk,3,cmdtext);
        dcmd(back,4,cmdtext);
        return 0;
} 


Here Is My Error:

PHP код:

C:\Users\Immortal\Desktop\Classified Gaming Roleplay\filterscripts\AFKSystem.pwn(82) : error 029: invalid expression, assumed zero
C:\Users\Immortal\Desktop\Classified Gaming Roleplay\filterscripts\AFKSystem.pwn(82) : error 017: undefined symbol "cmd_afkhelp"
C:\Users\Immortal\Desktop\Classified Gaming Roleplay\filterscripts\AFKSystem.pwn(82) : error 029: invalid expression, assumed zero
C:\Users\Immortal\Desktop\Classified Gaming Roleplay\filterscripts\AFKSystem.pwn(82) : fatal error 107: too many error messages on one line
Compilation aborted.Pawn compiler 3.2.3664              Copyright (c) 1997-2006, ITB CompuPhase
4 Errors. 


[Sabur]

......

[Immortal99]

I am getting this error trying to compile:

PHP код:

C:\Users\Immortal\Desktop\Classified Gaming Roleplay\filterscripts\AFKSystem.pwn(41) : error 017: undefined symbol "ReturnPlayerName"
C:\Users\Immortal\Desktop\Classified Gaming Roleplay\filterscripts\AFKSystem.pwn(57) : error 017: undefined symbol "ReturnPlayerName"
C:\Users\Immortal\Desktop\Classified Gaming Roleplay\filterscripts\AFKSystem.pwn(74) : error 054: unmatched closing brace ("}")
Pawn compiler 3.2.3664              Copyright (c) 1997-2006, ITB CompuPhase
3 Errors. 


[Darkwood17]

Never combine more than one command processor, it will make the other one not being called.

Sabur's code will give you a error because there is undefined function ReturnPlayerName.
Use the GetPlayerName method that is in your original post's code.

[Immortal99]

Can you help me fix it please?

[Sabur]

PHP код:

//-------------------------[Includes]-------------------------------------//
#include <a_samp>
#include <zcmd>
#pragma tabsize 0
//-------------------------[Color Defines]-------------------------------------//
#define COLOR_WHITE 0xFFFFFFAA
#define COLOR_GREEN 0x00FF00AA
#define COLOR_RED 0xFF0000AA
#define COLOR_LIGHTBLUE 0x33CCFFAA
#define COLOR_YELLOW 0xFFFF00AA
enum Player
{
    AFKstatus
}
new PlayerInfo[MAX_PLAYERS][Player];
public OnFilterScriptInit()
{
        print("\n--------------------------------------");
        print("Elite Gaming Away From Keyboard System Loaded!");
        print("--------------------------------------\n");
        return 1;
}
public OnFilterScriptExit()
{
        return 1;
}
CMD:afk(playerid, params[])
{
    new
    string[128];
    
    if(PlayerInfo[playerid][AFKstatus])
       return SendClientMessage(playerid, COLOR_RED, "SERVER: {FFFFFF}You are already /afk.");
       
    new
    name[24];
    GetPlayerName(playerid, name, sizeof(name));
    format(string, sizeof(string), "*{FFFFFF} %s is now AFK.", name);
    SendClientMessageToAll(COLOR_YELLOW, string);
    TogglePlayerControllable(playerid, 0);
    SetPlayerVirtualWorld(playerid, GetPlayerVirtualWorld(playerid) + 50);
    PlayerInfo[playerid][AFKstatus] = 1;
    return 1;
}
CMD:back(playerid, params[])
{
    new
    string[128];
    
    if(!PlayerInfo[playerid][AFKstatus])
       return SendClientMessage(playerid, COLOR_RED, "SERVER: {FFFFFF}You aren't /afk.");
       
    new
    name[24];
    GetPlayerName(playerid, name, sizeof(name));
    format(string, sizeof(string), "*{FFFFFF} %s is now back!", name);
    SendClientMessageToAll(COLOR_YELLOW, string);
    TogglePlayerControllable(playerid, 1);
    SetPlayerVirtualWorld(playerid, GetPlayerVirtualWorld(playerid) - 50);
    PlayerInfo[playerid][AFKstatus] = 0;
    
    return 1;
}
CMD:afkhelp(playerid, params [])
{
    SendClientMessage(playerid, COLOR_RED, "____Elite Gaming Away From Keyboard Help____");
    SendClientMessage(playerid, COLOR_WHITE, "To go in AFK Status use /afk");
    SendClientMessage(playerid, COLOR_WHITE, "To get back into your normal status use /back");
    return 1;
}
public OnPlayerDisconnect(playerid, reason)
{
        PlayerInfo[playerid][AFKstatus] = 0;
        return 1;
}
public OnPlayerText(playerid, text[])
{
        if (PlayerInfo[playerid][AFKstatus] == 1)
        {
                SendClientMessage(playerid, COLOR_RED, "SERVER:{FFFFFF} You need to type /back to speak");
                return 0;
        }
        else if (PlayerInfo[playerid][AFKstatus] == 0)
        {
                return 1;
        }
        return 1;
} 


just paste it, now it will work.

[Immortal99]

Thanks Sabur & Darkwood17. I +rep Sabur & +rep Darkwood17 for helping me