[Facerafter]

This is my cellphone system.
But if I call them and hangup. After that call them agian, the message "This number is busy" shows while is not on the phone.

pawn Код:

CMD:call(playerid, params[])
{
    new number, string[128], done;
    if(!IsPlayerLoggedIn(playerid)) return SendClientMessage(playerid, COLOR_GREY, "You need to login first before using any command.");
    if(!PlayerInfo[playerid][pHasCellphone]) return SendClientMessage(playerid, COLOR_GREY, "You don't own a cellphone.");
    if(!PlayerInfo[playerid][pCellphone]) return SendClientMessage(playerid, COLOR_GREY, "You don't have a simcard.");
    if(sscanf(params, "i", number)) return SendClientMessage(playerid, COLOR_WHITE, "USAGE: /call [number]");
    if(PhoneOff[playerid]) return SendClientMessage(playerid, COLOR_GREY, "Your phone is turned off.");
    if(Calling[playerid] == 1 || BeingCalled[playerid] == 1) return SendClientMessage(playerid, COLOR_GREY, "You are already on a call.");
    if(number == 0) return SendClientMessage(playerid, COLOR_GREY, "Invalid phone number.");
    format(string, sizeof(string), "* %s takes out their cellphone and starts calling a number.", GetPlayerNameEx(playerid));
    SendNearbyMessage(playerid, 15, string, COLOR_PURPLE, COLOR_PURPLE, COLOR_PURPLE, COLOR_PURPLE, COLOR_PURPLE);
    if(number == 911)
    {
        Calling[playerid] = 1;
        Call911[playerid] = 1;
        SetPlayerSpecialAction(playerid, SPECIAL_ACTION_USECELLPHONE);
        SendClientMessage(playerid, COLOR_YELLOW, "[Cellphone]: You are connected to the LSPD emergency line, please explain your emergency.");
    }
    foreach(Player, i)
    {
        if(PlayerInfo[i][pCellphone] == number)
        {
            if(PhoneOff[i]) return SendClientMessage(playerid, COLOR_GREY, "Player has their phone turned off.");
            if(BeingCalled[i] || Calling[i]) return SendClientMessage(playerid, COLOR_GREY, "Number busy.");
            Calling[playerid] = 1;
            BeingCalled[i] = 1;
            Called[playerid] = i;
            Caller[i] = playerid;
            SendClientMessage(playerid, COLOR_ORANGE, " The cellphone is ringing, wait for someone to pickup.");
            format(string, sizeof(string), "* %s's cellphone starts ringing.", GetPlayerNameEx(i));
            SendNearbyMessage(i, 15, string, COLOR_PURPLE, COLOR_PURPLE, COLOR_PURPLE, COLOR_PURPLE, COLOR_PURPLE);
            format(string, sizeof(string), " [Cellphone]: Incoming call from %s, Ph: %d", GetPlayerNameEx(playerid), PlayerInfo[playerid][pCellphone]);
            SendClientMessage(i, COLOR_YELLOW, string);
            SendClientMessage(i, COLOR_WHITE, " Type /pickup to answer or /hangup to cancel the incoming call.");
            done = 1;
            SetPlayerSpecialAction(playerid, SPECIAL_ACTION_USECELLPHONE);
        }
    }
    if(done != 1)
    {
        SendClientMessage(playerid, COLOR_GREY, "Number is not currently available.");
    }
    return 1;
}

pawn Код:

CMD:hangup(playerid, params[])
{
    new string[128];
    if(!IsPlayerLoggedIn(playerid)) return SendClientMessage(playerid, COLOR_GREY, "You need to login first before using any command.");
    if(!PlayerInfo[playerid][pHasCellphone]) return SendClientMessage(playerid, COLOR_GREY, "You don't own a cellphone.");
    if(!BeingCalled[playerid] && !Calling[playerid]) return SendClientMessage(playerid, COLOR_GREY, "You are not on a call nor is anybody calling you.");
    format(string, sizeof(string), "* %s puts their cellphone away.", GetPlayerNameEx(playerid));
    SendNearbyMessage(playerid, 15, string, COLOR_PURPLE, COLOR_PURPLE, COLOR_PURPLE, COLOR_PURPLE, COLOR_PURPLE);
    SendClientMessage(playerid, COLOR_ORANGE, " You have hungup the line.");
    if(BeingCalled[playerid]) SendClientMessage(Caller[playerid], COLOR_ORANGE, " They hungup the line.");
    else if(Calling[playerid]) SendClientMessage(Called[playerid], COLOR_ORANGE, " They hungup the line.");
    if(Call911[playerid]) return SendClientMessage(playerid, COLOR_GREY, "You can't hangup on a 911 call.");
    //
    SetPlayerSpecialAction(playerid, SPECIAL_ACTION_STOPUSECELLPHONE);
    if(Calling[playerid])
    {
        SetPlayerSpecialAction(Called[playerid], SPECIAL_ACTION_STOPUSECELLPHONE);
        format(string, sizeof(string), "[Cellphone] Phonecall lasted for %d seconds, price: $%d", CallTime[playerid], CallTime[playerid]*10/100);
        SendClientMessage(playerid, COLOR_YELLOW, string);
        GiveSafeMoney(playerid, -(CallTime[playerid]*10/100));
        TaxMoney += (CallTime[playerid]*10/100);
        Calling[playerid] = 0;
        BeingCalled[playerid] = 0;
        Caller[playerid] = -1;
        CallTime[playerid] = 0;
        Called[playerid] = -1;
    }
    else if(Calling[Caller[playerid]])
    {
        SetPlayerSpecialAction(Called[playerid], SPECIAL_ACTION_STOPUSECELLPHONE);
        format(string, sizeof(string), "[Cellphone] Phonecall lasted for %d seconds, price: $%d", CallTime[Caller[playerid]], CallTime[Caller[playerid]]*10/100);
        SendClientMessage(Caller[playerid], COLOR_YELLOW, string);
        GiveSafeMoney(Caller[playerid], -(CallTime[Caller[playerid]]*10/100));
        TaxMoney += (CallTime[Caller[playerid]]*10/100);
        Calling[Called[playerid]] = 0;
        BeingCalled[Called[playerid]] = 0;
        Caller[Called[playerid]] = -1;
        CallTime[Called[playerid]] = 0;
        Called[Called[playerid]] = -1;
    }
    return 1;
}

[Nero_3D]

How about that ?

pawn Код:

//
    new
        caller,
        receiver
    ;
    if(Calling[playerid]) {
        caller = playerid;
        receiver = Called[playerid];
    } else {
        caller = Caller[playerid];
        receiver = playerid;
    }
    SetPlayerSpecialAction(caller, SPECIAL_ACTION_STOPUSECELLPHONE);
    SetPlayerSpecialAction(receiver, SPECIAL_ACTION_STOPUSECELLPHONE);

    new
        time = CallTime[caller],
        money = time / 60 * 8 // 8 cent per minute :p
    ;
    format(string, sizeof(string), "[Cellphone] Phonecall lasted for %d seconds, price: $%d", time, money);
    SendClientMessage(caller, COLOR_YELLOW, string);

    GiveSafeMoney(caller, -money);
    TaxMoney += money;

    Calling[caller] = 0;
    BeingCalled[receiver] = 0;
    Called[caller] = -1;
    Caller[receiver] = -1;
    CallTime[caller] = 0;