[joeri55]

Hello,

I've checked the San Andreas File Functions but I couldn't find the one that will disable your own NameTag.
I want something like a Mask. How can I make something like that?

I really need help..

Thankyou

[Correlli]

ShowPlayerNameTagForPlayer

[Calgon]

You wouldn't find it in 'file functions', it would be in the 'samp' include.

And use something like this (from the wiki):

pawn Код:

for(new i = 0; i < MAX_PLAYERS; i++) ShowPlayerNameTagForPlayer(playerid, i, false);

[joeri55]

Doesn't works,

Does anyone has a mask system?

[Correlli]

Try to search in the gamemode-showroom, probably some script has it.

[joeri55]

Good option,

Do you know a GM?

[Correlli]

I'm not sure but i think Los Angeles Role Play (LARP) has it.

[Calgon]

pawn Код:

dcmd_mask(playerid, params[])
{
    new userid, string[128];
    if (sscanf(params, "ud", userid)) SendClientMessage(playerid, COLOR_WHITE, "SYNTAX - /mask [playerid]");
    else
    {
        if(IsPlayerConnected(userid))
        {
            for(new i = 0; i < MAX_PLAYERS; i++)
            {
                ShowPlayerNameTagForPlayer(i, userid, false);
            }
        }
    }
    return 1;
}

Something like that?

[joeri55]

Код:

C:\Documents and Settings\Joeri\Bureaublad\samp server\samp02X\gamemodes\Wasted.pwn(6221) : error 017: undefined symbol "userid"
Pawn compiler 3.2.3664	 	 	Copyright © 1997-2006, ITB CompuPhase


1 Error.

Hmmm?

new userid; ?

[Clavius]

For Calgon's code:

pawn Код:

if (sscanf(params, "u", userid)) return SendClientMessage(playerid, COLOR_WHITE, "SYNTAX - /mask [playerid]");

Removed the 'd'
Also the string is unnecessary.

[joeri55]

All doesn't works

Can anyone make a Filterscript for this pl0x?

[Calgon]

Quote:

Originally Posted by player007 For Calgon's code: pawn Код: if (sscanf(params, "u", userid)) return SendClientMessage(playerid, COLOR_WHITE, "SYNTAX - /mask [playerid]"); Removed the 'd' Also the string is unnecessary.

My bad, I have the general ud as a bind with the string, for when I'm scripting (saves me years).

What does it say when you try to remove the 'd' in the sscanf() bit?

[joeri55]

Can't you just make a FS from it 'cause it gives like 100 errors if I do exacly what you say.

[Correlli]

This will hide your name for every connected player.

pawn Код:

for(new i = 0; i < MAX_PLAYERS; i++)
{
  if(IsPlayerConnected(i))
  {
    ShowPlayerNameTagForPlayer(i, playerid, 0);
  }
}

and this will show your name for every connected player:

pawn Код:

for(new i = 0; i < MAX_PLAYERS; i++)
{
  if(IsPlayerConnected(i))
  {
    ShowPlayerNameTagForPlayer(i, playerid, 1);
  }
}

I think it's not hard for you to continue from here.

[Clavius]

Step-to-step:
1) Define dcmd: add this to the top (if you don't already have it)

Код:

#define dcmd(%1,%2,%3) if (!strcmp((%3)[1], #%1, true, (%2)) && ((((%3)[(%2) + 1] == '\0') && (dcmd_%1(playerid, ""))) || (((%3)[(%2) + 1] == ' ') && (dcmd_%1(playerid, (%3)[(%2) + 2]))))) return 1

2) Add sscanf to your script (if you don't already have it): GET SSCANF HERE

3) Go to your OnPlayerCommandText, and add

pawn Код:

dcmd(mask, 4, cmdtext);

4) Add this somewhere to your script, anywhere as long as it is not in any other callback:

pawn Код:

dcmd_mask(playerid, params[])
{
    new userid;
    if (sscanf(params, "u", userid) != 0) return SendClientMessage(playerid, SOME_COLOR, "USAGE: /mask [playerid or name]");
    if (IsPlayerConnected(userid))
    {
        for(new i = 0; i < MAX_PLAYERS; i++)
        {
            ShowPlayerNameTagForPlayer(i, userid, false);
        }
        if (userid != playerid) SendClientMessage(playerid, SOME_COLOR, "[SUCCESS] Target player is now masked!");
        SendClientMessage(userid, SOME_COLOR, "You have been masked!");
    }
    else SendClientMessage(playerid, SOME_COLOR, "[FAIL] Target player is not connected!");
    return 1;
}

Now you should be able to make an unmask command easily!

[joeri55]

Thankyou playaaar :P

[joeri55]

I get this problems:

Код:

C:\Documents and Settings\Joeri\Bureaublad\samp server\samp02X\gamemodes\Wasted.pwn(9643) : error 017: undefined symbol "dcmd_mask"
C:\Documents and Settings\Joeri\Bureaublad\samp server\samp02X\gamemodes\Wasted.pwn(9645) : warning 217: loose indentation
C:\Documents and Settings\Joeri\Bureaublad\samp server\samp02X\gamemodes\Wasted.pwn(9645) : error 017: undefined symbol "dcmd_mask"
C:\Documents and Settings\Joeri\Bureaublad\samp server\samp02X\gamemodes\Wasted.pwn(9648) : error 017: undefined symbol "params"
C:\Documents and Settings\Joeri\Bureaublad\samp server\samp02X\gamemodes\Wasted.pwn(9663) : warning 225: unreachable code
C:\Documents and Settings\Joeri\Bureaublad\samp server\samp02X\gamemodes\Wasted.pwn(9663) : warning 217: loose indentation
Pawn compiler 3.2.3664	 	 	Copyright © 1997-2006, ITB CompuPhase


3 Errors.

In this part:

Код:

dcmd_mask(playerid, params[])
{
new userid;
if (sscanf(params, "u", userid) != 0) return SendClientMessage(playerid, COLOR_GRAD1, "USAGE: /mask [playerid or name]");
if (IsPlayerConnected(userid))
{
for(new i = 0; i < MAX_PLAYERS; i++)
{
ShowPlayerNameTagForPlayer(i, userid, false);
}
if (userid != playerid) SendClientMessage(playerid, COLOR_GRAD1, "[SUCCESS] Target player is now masked!");
SendClientMessage(userid, COLOR_GRAD1, "You have been masked!");
}
else SendClientMessage(playerid, COLOR_GRAD1, "[FAIL] Target player is not connected!");
return 1;
}

[Calgon]

Add this to the top of your script:

pawn Код:

#define dcmd(%1,%2,%3) if (!strcmp((%3)[1], #%1, true, (%2)) && ((((%3)[(%2) + 1] == '\0') && (dcmd_%1(playerid, ""))) || (((%3)[(%2) + 1] == ' ') && (dcmd_%1(playerid, (%3)[(%2) + 2]))))) return 1

Add this somewhere that's not in a function:

pawn Код:

stock sscanf(string[], format[], {Float,_}:...)
{
    #if defined isnull
        if (isnull(string))
    #else
        if (string[0] == 0 || (string[0] == 1 && string[1] == 0))
    #endif
        {
            return format[0];
        }
    #pragma tabsize 4
    new
        formatPos = 0,
        stringPos = 0,
        paramPos = 2,
        paramCount = numargs(),
        delim = ' ';
    while (string[stringPos] && string[stringPos] <= ' ')
    {
        stringPos++;
    }
    while (paramPos < paramCount && string[stringPos])
    {
        switch (format[formatPos++])
        {
            case '\0':
            {
                return 0;
            }
            case 'i', 'd':
            {
                new
                    neg = 1,
                    num = 0,
                    ch = string[stringPos];
                if (ch == '-')
                {
                    neg = -1;
                    ch = string[++stringPos];
                }
                do
                {
                    stringPos++;
                    if ('0' <= ch <= '9')
                    {
                        num = (num * 10) + (ch - '0');
                    }
                    else
                    {
                        return -1;
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num * neg);
            }
            case 'h', 'x':
            {
                new
                    num = 0,
                    ch = string[stringPos];
                do
                {
                    stringPos++;
                    switch (ch)
                    {
                        case 'x', 'X':
                        {
                            num = 0;
                            continue;
                        }
                        case '0' .. '9':
                        {
                            num = (num << 4) | (ch - '0');
                        }
                        case 'a' .. 'f':
                        {
                            num = (num << 4) | (ch - ('a' - 10));
                        }
                        case 'A' .. 'F':
                        {
                            num = (num << 4) | (ch - ('A' - 10));
                        }
                        default:
                        {
                            return -1;
                        }
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num);
            }
            case 'c':
            {
                setarg(paramPos, 0, string[stringPos++]);
            }
            case 'f':
            {
                setarg(paramPos, 0, _:floatstr(string[stringPos]));
            }
            case 'p':
            {
                delim = format[formatPos++];
                continue;
            }
            case '\'':
            {
                new
                    end = formatPos - 1,
                    ch;
                while ((ch = format[++end]) && ch != '\'') {}
                if (!ch)
                {
                    return -1;
                }
                format[end] = '\0';
                if ((ch = strfind(string, format[formatPos], false, stringPos)) == -1)
                {
                    if (format[end + 1])
                    {
                        return -1;
                    }
                    return 0;
                }
                format[end] = '\'';
                stringPos = ch + (end - formatPos);
                formatPos = end + 1;
            }
            case 'u':
            {
                new
                    end = stringPos - 1,
                    id = 0,
                    bool:num = true,
                    ch;
                while ((ch = string[++end]) && ch != delim)
                {
                    if (num)
                    {
                        if ('0' <= ch <= '9')
                        {
                            id = (id * 10) + (ch - '0');
                        }
                        else
                        {
                            num = false;
                        }
                    }
                }
                if (num && IsPlayerConnected(id))
                {
                    setarg(paramPos, 0, id);
                }
                else
                {
                    #if !defined foreach
                        #define foreach(%1,%2) for (new %2 = 0; %2 < MAX_PLAYERS; %2++) if (IsPlayerConnected(%2))
                        #define __SSCANF_FOREACH__
                    #endif
                    string[end] = '\0';
                    num = false;
                    new
                        name[MAX_PLAYER_NAME];
                    id = end - stringPos;
                    foreach (Player, playerid)
                    {
                        GetPlayerName(playerid, name, sizeof (name));
                        if (!strcmp(name, string[stringPos], true, id))
                        {
                            setarg(paramPos, 0, playerid);
                            num = true;
                            break;
                        }
                    }
                    if (!num)
                    {
                        setarg(paramPos, 0, INVALID_PLAYER_ID);
                    }
                    string[end] = ch;
                    #if defined __SSCANF_FOREACH__
                        #undef foreach
                        #undef __SSCANF_FOREACH__
                    #endif
                }
                stringPos = end;
            }
            case 's', 'z':
            {
                new
                    i = 0,
                    ch;
                if (format[formatPos])
                {
                    while ((ch = string[stringPos++]) && ch != delim)
                    {
                        setarg(paramPos, i++, ch);
                    }
                    if (!i)
                    {
                        return -1;
                    }
                }
                else
                {
                    while ((ch = string[stringPos++]))
                    {
                        setarg(paramPos, i++, ch);
                    }
                }
                stringPos--;
                setarg(paramPos, i, '\0');
            }
            default:
            {
                continue;
            }
        }
        while (string[stringPos] && string[stringPos] != delim && string[stringPos] > ' ')
        {
            stringPos++;
        }
        while (string[stringPos] && (string[stringPos] == delim || string[stringPos] <= ' '))
        {
            stringPos++;
        }
        paramPos++;
    }
    do
    {
        if ((delim = format[formatPos++]) > ' ')
        {
            if (delim == '\'')
            {
                while ((delim = format[formatPos++]) && delim != '\'') {}
            }
            else if (delim != 'z')
            {
                return delim;
            }
        }
    }
    while (delim > ' ');
    return 0;
}

[joeri55]

I did that but it didn't help...