SA-MP Forums Archive
[Ajuda] Oque hб de errado nessa funзгo ?! - Printable Version

+- SA-MP Forums Archive (https://sampforum.blast.hk)
+-- Forum: Non-English (https://sampforum.blast.hk/forumdisplay.php?fid=9)
+--- Forum: Languages (https://sampforum.blast.hk/forumdisplay.php?fid=33)
+---- Forum: Português/Portuguese (https://sampforum.blast.hk/forumdisplay.php?fid=34)
+---- Thread: [Ajuda] Oque hб de errado nessa funзгo ?! (/showthread.php?tid=569605)


Oque hб de errado nessa funзгo ?! - Yak - 01.04.2015

Bem, eu achei um pouco simples, porem pra mim ta dificil de resolver o erro :c

Erro: Ao entrar no suposto caminhгo, simplesmente ele entra normal sem ao menos fazer qualquer tipo de verificaзгo!

Codigo:

PHP код:
public OnPlayerStateChange(playerid, newstate, oldstate)
{
     new pName[MAX_PLAYER_NAME], info[128];
     if(newstate == PLAYER_STATE_DRIVER)
    if(Org[playerid] == Agente)
    {
        if(IsPlayerInVehicle(playerid,Caminhao[0]))
        {
            SetPlayerCheckpoint(playerid,2873.1750,921.2672,10.7500,3.0);
            GetPlayerName(playerid, pName, MAX_PLAYER_NAME);
            format(info, sizeof(info), "| AVISO | O Caminhгo dos Mercenбrios foi coletado pelo player %s e estб em transporte!", pName);
            SendClientMessageToAll(AmareloClaro,pName);
            return 1;
            }
                else
            {
            if(newstate == PLAYER_STATE_DRIVER)
            RemovePlayerFromVehicle(playerid);
            SendClientMessage(playerid, Vermelho, "| ERRO | Vocк nгo pode pegar esse veiculo !");
            return 1;
        }
    }
    return 1;
} 
Obrigado !

@Edit

Caso achem que o 'erro' seja por causa dos return ali, mesmo sem os dois primeiros ainda sim continuava a nгo fazer efeito !

Re: Oque hб de errado nessa funзгo ?! - CucaBeludo - 01.04.2015

PHP код:
public OnPlayerStateChange(playerid, newstate, oldstate)
{
    new VehID = GetPlayerVehicleID(playerid);
    if(newstate == PLAYER_STATE_DRIVER)
    {
        if(VehID == Caminhao[0])
        {
            if(Org[playerid] != Agente)
              {
                  SendClientMessage(playerid,-1, "Este carro nгo estб disponнvel para sua organizaзгo !");
                  RemovePlayerFromVehicle(playerid);
                  return 1;
              }
            SetPlayerCheckpoint(playerid,2873.1750,921.2672,10.7500,3.0);
            GetPlayerName(playerid, pName, MAX_PLAYER_NAME);
            format(info, sizeof(info), "| AVISO | O Caminhгo dos Mercenбrios foi coletado pelo player %s e estб em transporte!", pName);
            SendClientMessageToAll(AmareloClaro,pName);
        }
    }
    return 1;
} 
Se vocк tiver uma lista de veнculos criados, por exemplo:
Код:
Caminhao[0] = ...
Caminhao[1] = ...
Caminhao[2] = ...
Caminhao[3] = ...
Faзa isso que estб abaixo, pois vocк nгo terб que repetir para todos os Caminhхes.

PHP код:
public OnPlayerStateChange(playerid, newstate, oldstate)
{
    new VehID = GetPlayerVehicleID(playerid);
    if(newstate == PLAYER_STATE_DRIVER)
    {
        for(new i = 0; i < sizeof(Caminhao); i++)
        {
            if(VehID == Caminhao[i])
            {
                if(Org[playerid] != Agente)
                {
                    SendClientMessage(playerid,-1, "Este carro nгo estб disponнvel para sua organizaзгo !");
                    RemovePlayerFromVehicle(playerid);
                    return 1;
                }
                SetPlayerCheckpoint(playerid,2873.1750,921.2672,10.7500,3.0);
                GetPlayerName(playerid, pName, MAX_PLAYER_NAME);
                format(info, sizeof(info), "| AVISO | O Caminhгo dos Mercenбrios foi coletado pelo player %s e estб em transporte!", pName);
                SendClientMessageToAll(AmareloClaro,pName);
            }
        }
    }
    return 1;
} 
----------------------------------------

Outro erro, veja esta linha de seu cуdigo:
PHP код:
SendClientMessageToAll(AmareloClaro,pName); 
O correto:
PHP код:
SendClientMessageToAll(AmareloClaro,info); 


Re: Oque hб de errado nessa funзгo ?! - Yak - 01.04.2015

Ok, pela logica seu codigo й funcional, mas acontece de dar erro na verificaзгo das organizaзхes ao entrar no veiculo.
serб que tem a ver como a organizaзгo estб definida ?

por exemplo: pode dar conflito se pra trocar de organizaзгo for um comando ?

e existe algum jeito de eu setar outra organizaзгo ao executar um comando ? Obrigado !

Re: Oque hб de errado nessa funзгo ?! - CucaBeludo - 01.04.2015

No comeзo de seu gamemode, deve estar definido assim:

PHP код:
#define Agente (NЪMERO) 
Entгo, para vocк setar a profissгo para um jogar:

PHP код:
Org[playerid] = Agente; 
Й o seguinte cara, procure tutoriais aqui no Fуrum e estude esse meu cуdigo:

PHP код:
#include <a_samp>
#include <zcmd>
#include <sscanf2>
#include <dof2>
#define QUANTIDADE_PROFS 6
new _NameProfs[QUANTIDADE_PROFS][40] = {
    "Desempregado",
    "Camioneiro",
    "Taxista",
    "Mecanico",
    "Seguranзa",
    "Mendigo"
};
new Float:_SpawnProfs[QUANTIDADE_PROFS][3] = {
    {1958.3783,1343.1572,15.3746},
    {2199.6531,1393.3678,10.8203},
    {2483.5977,1222.0825,10.8203},
    {2637.2712,1129.2743,11.1797},
    {2000.0106,1521.1111,17.0625},
    {2024.8190,1917.9425,12.3386}
};
new _CoresProfs[QUANTIDADE_PROFS] = {
    0xFFFFFFFF,
    0xFFFF80FF,
    0x80FF80FF,
    0x80FFFFFF,
    0x0080FFFF,
    0xFF0000FF
};
new _Profissao[MAX_PLAYERS];
new VehiclesDesempregado[5];
main()
{
    print("\n----------------------------------");
    print(" Prof's... LOADED!");
    print("----------------------------------\n");
}
CMD:setprof(playerid, params[])
{
    new xString[128];
    if(sscanf(params, "ud", params[0], params[1])) return SendClientMessage(playerid, 0xFF0000FF, "/setprof [ID] [PROF]");
    if(!IsPlayerConnected(params[0])) return SendClientMessage(playerid, 0xFF0000FF, "Jogador nгo conectado.");
    if(params[1] >= QUANTIDADE_PROFS || params[1] < 0) return SendClientMessage(playerid, 0xFF0000FF, ":::: 0-5 ::::");
    _Profissao[params[0]] = params[1];
    
    format(xString, sizeof(xString), "Profissгo: %s | Jogador %s", _NameProfs[_Profissao[params[0]]], iName(params[0]));
    SendClientMessage(playerid, _CoresProfs[_Profissao[params[0]]], xString);
    format(xString, sizeof(xString), "Sua Profissгo agora й: %s", _NameProfs[_Profissao[params[0]]]);
    SendClientMessage(params[0], _CoresProfs[_Profissao[params[0]]], xString);
    
    OnPlayerSpawn(params[0]);
    return 1;
}
public OnGameModeInit()
{
    SetGameModeText("Blank Script");
    for(new i; i < 300; ++i) AddPlayerClass(i, 1958.3783, 1343.1572, 15.3746, 269.1425, 0, 0, 0, 0, 0, 0);
    VehiclesDesempregado[0] = CreateVehicle(498, 2039.5201, 1350.4873, 10.7161, 0.0000, -1, -1, 100);
    VehiclesDesempregado[1] = CreateVehicle(498, 2039.7744, 1358.1622, 10.7161, 0.0000, -1, -1, 100);
    VehiclesDesempregado[2] = CreateVehicle(498, 2039.8103, 1365.6306, 10.7161, 0.0000, -1, -1, 100);
    VehiclesDesempregado[3] = CreateVehicle(498, 2039.5736, 1372.8027, 10.7161, 0.0000, -1, -1, 100);
    VehiclesDesempregado[4] = CreateVehicle(504, 2039.6356, 1380.0780, 10.4746, 0.0000, -1, -1, 100);
    return 1;
}
public OnGameModeExit()
{
    DOF2_Exit();
    return 1;
}
public OnPlayerRequestClass(playerid, classid)
{
    SetPlayerPos(playerid, 1958.3783, 1343.1572, 15.3746);
    SetPlayerCameraPos(playerid, 1958.3783, 1343.1572, 15.3746);
    SetPlayerCameraLookAt(playerid, 1958.3783, 1343.1572, 15.3746);
    return 1;
}
public OnPlayerConnect(playerid)
{
    if(!DOF2_FileExists(pConta(playerid)))
    {
        DOF2_CreateFile(pConta(playerid));
        DOF2_SetInt(pConta(playerid), "Profissao", 0);
    }
    
    _Profissao[playerid] = DOF2_GetInt(pConta(playerid), "Profissao");
    new kString[128];
    format(kString, sizeof(kString), "Sua profissгo: %s", _NameProfs[_Profissao[playerid]]);
    SendClientMessage(playerid, _CoresProfs[_Profissao[playerid]], kString);
    return 1;
}
public OnPlayerDisconnect(playerid, reason)
{
    DOF2_SetInt(pConta(playerid), "Profissao", _Profissao[playerid]);
    _Profissao[playerid] = 0;
    return 1;
}
public OnPlayerSpawn(playerid)
{
    SetPlayerPos(playerid, _SpawnProfs[_Profissao[playerid]][0],  _SpawnProfs[_Profissao[playerid]][1], _SpawnProfs[_Profissao[playerid]][2]);
    SetPlayerColor(playerid, _CoresProfs[_Profissao[playerid]]);
    return 1;
}
public OnPlayerStateChange(playerid, newstate, oldstate)
{
    new VehID = GetPlayerVehicleID(playerid);
    if(newstate == PLAYER_STATE_DRIVER)
    {
        for(new i = 0; i < sizeof(VehiclesDesempregado); i++)
        {
            if(VehID == VehiclesDesempregado[i] && _Profissao[playerid] != 0)
            {
                SendClientMessage(playerid,-1, "Este carro nгo estб disponнvel para sua organizaзгo !");
                RemovePlayerFromVehicle(playerid);
            }
        }
    }
    return 1;
}
stock iName(playerid)
{
    new _iNome[MAX_PLAYER_NAME];
    GetPlayerName(playerid, _iNome, sizeof(_iNome));
    return _iNome;
}
stock pConta(id)
{
    new _cString[128];
    format(_cString, sizeof(_cString), "Contas/%s", iName(id));
    return _cString;
} 


Re: Oque hб de errado nessa funзгo ?! - Yak - 01.04.2015

Obrigado por TODO seu suporto cara, valeo mesmo.

estudarei ^^