CMD:setlevel(playerid,params[])
{
	if(AccInfo[playerid][LoggedIn] == 1)
	{
		if(IsPlayerAdmin(playerid) || AccInfo[playerid][Level] >= 9)
		{
		    new string[128], userid, player1, level;
		    //------------------------------------------------------------------
		    if(sscanf(params, "ud", player1, level)) return
		    SendClientMessage(playerid, LIGHTBLUE2, "{FFFFFF}Usage: {00FF00}/setlevel{FFFFFF} [PlayerID] [Level (0-10)]") &&
  			SendClientMessage(playerid, orange, "{FFFFFF}Function: Will set the Level of Administration of the Specific Player");
			//------------------------------------------------------------------
			if(IsPlayerConnected(player1) && player1 != INVALID_PLAYER_ID)
			{
				if(AccInfo[player1][LoggedIn] == 1)
				{
				    //----------------------------------------------------------
					if(level > ServerInfo[MaxAdminLevel]) return
					SendClientMessage(playerid,red,"ERROR: Invalid Level");
					//----------------------------------------------------------
					if(level == AccInfo[player1][Level]) return
					SendClientMessage(playerid,red,"ERROR: Player is already this level");
					//----------------------------------------------------------
	       			SendCommandToAdmins(playerid,"SetLevel");
					//----------------------------------------------------------
					if(level > 0)	format(string, 128, "{FFFFFF}Administrator {FFFFFF}%s {FFFFFF}has set you to Administrator Status  Level:{00FF00} %d",PlayerName2(playerid), level);
					else			format(string, 128, "{FFFFFF}Administrator {FFFFFF}%s {FFFFFF}has set you to Player Status  Level: {00FF00}%d", PlayerName2(playerid), level);
					//----------------------------------------------------------
					SendClientMessage(player1,LIGHTBLUE,string);
					//----------------------------------------------------------
					if(level > AccInfo[player1][Level])	GameTextForPlayer(player1,"Promoted", 2000, 3);
					else								GameTextForPlayer(player1,"Demoted", 2000, 3);
					//----------------------------------------------------------
					format(string, 128, "{FFFFFF}You have Successfully given %s Level %d", 	PlayerName2(player1), level);
					SendClientMessage(playerid, yellow, string);
					format(string, 128, "{FFFFFF}Administrator{00FF00} %s {FFFFFF}has made{00FF00} %s {FFFFFF}Admin Level {00FF00}%d", PlayerName2(playerid), PlayerName2(player1), level);
					SaveIn("AdminLog",string);
					//----------------------------------------------------------
					userid = BUD::GetNameUID(PlayerName2(player1));
					BUD::SetIntEntry(userid,"Admin",level);
					AccInfo[player1][Level] = level;
					PlayerPlaySound(player1,1057,0.0,0.0,0.0);
					//----------------------------------------------------------
					return 1;
				}
				else return SendClientMessage(playerid,red,"ERROR: This player is not Registred or Logged!");
			}
			else return ErrorMessages(playerid, 2);
		}
		else return ErrorMessages(playerid, 12);
	}
	else return SendClientMessage(playerid,red,"ERROR: You must be logged in to use this command");
}
//++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
CMD:setvip(playerid,params[])
{
	if(IsPlayerAdmin(playerid))
	{
	    new string[128], userid, player1, type;
		//----------------------------------------------------------------------
  		if(sscanf(params, "ud", player1, type)) return
		SendClientMessage(playerid, LIGHTBLUE2, "{FFFFFF}Usage: {00FF00}/setvip {FFFFFF}[PlayerID] [VIP Level (0-10)]") &&
		SendClientMessage(playerid, orange, "{FFFFFF}Function: Will set the VIP Level of the Specific Player");
		//----------------------------------------------------------------------
		if(IsPlayerConnected(player1) && player1 != INVALID_PLAYER_ID)
		{
			if(AccInfo[player1][LoggedIn] == 1)
			{
   				//--------------------------------------------------------------
				if(type > 10 || type == AccInfo[player1][pVip]) return
				SendClientMessage(playerid, red, "ERROR: Player is already this Level or is an Invalid VIP Level!");
				//--------------------------------------------------------------
				format(string, 128, "{FFFFFF}Administrator {00FF00}%s {FFFFFF}has set your VIP Level to: {FFFFFF}%d", PlayerName2(playerid), type);
				SendClientMessage(player1, blue, string);
				//--------------------------------------------------------------
				if(type > AccInfo[player1][pVip])	GameTextForPlayer(player1,"Promoted ", 2000, 3);
				else								GameTextForPlayer(player1,"Demoted", 2000, 3);
				//--------------------------------------------------------------
				format(string, 128, "{FFFFFF}You have Successfully given {00FF00}%s{FFFFFF} VIP Level: {00FF00}%d", PlayerName2(player1), type);
				SendClientMessage(playerid, yellow, string);
				format(string, 128, "{FFFFFF}Administrator {00FF00}%s{FFFFFF} has made {00FF00}%s {FFFFFF}VIP Level {00FF00}%d", PlayerName2(playerid), PlayerName2(player1), type);
				SaveIn("AdminLog",string);
				//--------------------------------------------------------------
				userid = BUD::GetNameUID(PlayerName2(player1));
				BUD::SetIntEntry(userid, "Vip", type);
				AccInfo[player1][pVip] = type;
				PlayerPlaySound(player1,1057,0.0,0.0,0.0);
				return 1;
			}
			else return SendClientMessage(playerid, red, "ERROR: This player is not Registred or Logged!");
		}
		else return SendClientMessage(playerid, red, "ERROR: Player not connected!");
	}
	else return SendClientMessage(playerid, red, "ERROR: You must bee RCON to use this command!");
}

CMD:goto(playerid,params[])
{
   new teleid;
   if(sscanf(params,"u",teleid)) return SendClientMessage(playerid, red, "{FFFFFF}Usage:{00FF00}/goto {FFFFFF}[playerid]");
   if(!IsPlayerConnected(teleid)) return SendClientMessage(playerid, red, "{FFFFFF}Player is not connected");
   if(teleid == INVALID_PLAYER_ID) return SendClientMessage(playerid, red, "{FFFFFF}This isn't a valid player ID");
   if(tele[teleid]==1) return SendClientMessage(playerid, red, "{FFFFFF}Player has not enabled tele command");
   new Float:telex,Float:teley,Float:telez,int;
   GetPlayerPos(teleid,telex,teley,telez);
   int = GetPlayerInterior(teleid);
   if(IsPlayerInAnyVehicle(playerid) && GetPlayerState(playerid) == PLAYER_STATE_DRIVER)
  {
   new vid = GetPlayerVehicleID(playerid);
   SetVehiclePos(vid, telex, teley, telez+1);
   LinkVehicleToInterior(vid, int);
  }
   else
  {
   SetPlayerPos(playerid,telex,teley,telez+1);
   SetPlayerInterior(playerid,int);
  }
   return 1;
}