MYSQL R7 error - Printable Version

MYSQL R7 error - Printable Version

+- SA-MP Forums Archive (https://sampforum.blast.hk)
+-- Forum: SA-MP Scripting and Plugins (https://sampforum.blast.hk/forumdisplay.php?fid=8)
+--- Forum: Scripting Help (https://sampforum.blast.hk/forumdisplay.php?fid=12)
+--- Thread: MYSQL R7 error (/showthread.php?tid=510294)

MYSQL R7 error - Yves - 30.04.2014

Maybe a simple fix for you guys.

error 017: undefined symbol "query"

Код:

the query giving me the error.
mysql_function_query( connectionHandle, query[], bool:cache, callback[], format[], {Float,_}:... )

Re: MYSQL R7 error - BlAcKEdiTioN - 30.04.2014

include <mysql>

Re: MYSQL R7 error - Konstantinos - 30.04.2014

You should modify the line with your arguments and "query" is supposed to be either a string directly or a formatted string.

Re: MYSQL R7 error - Guest4390857394857 - 30.04.2014

Create
New query[500];
Then format it
And then use the query format.
It work i'm damn sure

Re: MYSQL R7 error - Yves - 30.04.2014

Quote:

Originally Posted by Konstantinos

You should modify the line with your arguments and "query" is supposed to be either a string directly or a formatted string.

Can you show me what you mean by that?

however, the query is not a string.

Quote:

Originally Posted by ShivRp

Create
New query[500];
Then format it
And then use the query format.
It work i'm damn sure

i did this didn't work and no need for 500

The full code

Код:

timer LoadingScreenTimer[100](playerid) 
{
	LoadingPercentage[playerid] ++;
	format(string, sizeof(string), "%d%%~n~~w~Loading...", LoadingPercentage[playerid]);
	TextDrawSetString(RegisterLoginTD[playerid][5], string);
	if(LoadingPercentage[playerid] == 100)
	{

	    SendClientMessage(playerid, COLOR_YELLOW, "Use keys up-down and right-left and when you select action press F!");
	    format(string, sizeof(string), "Welcome %s~n~~n~Please type your password!", GetName(playerid));
		TextDrawSetString(RegisterLoginTD[playerid][0], string);
		LoadingPercentage[playerid] = 0;
	    TextDrawHideForPlayer(playerid, RegisterLoginTD[playerid][5]);
		mysql_format(1, Query, "SELECT * FROM `test_table` WHERE `Name` = '%e'", GetName(playerid));
    	mysql_function_query( connectionHandle, query[], bool:cache, callback[], format[], {Float,_}:... )
		mysql_store_result();
		SelectedCharacter[playerid] = 0;

		if(mysql_num_rows() == 1)
		{
		    SendClientMessage(playerid, COLOR_LIME, "You are registered, please type your password!");
			CPLK[playerid] = repeat CheckPlayerLoginKeys(playerid);
			TextDrawSetString(RegisterLoginTD[playerid][2], "LOGIN   DELETE");
		}
		else
		{
		    SendClientMessage(playerid, COLOR_LIME, "You are not registered, please type your new password!");
			CPRK[playerid] = repeat CheckPlayerRegisterKeys(playerid);
			TextDrawSetString(RegisterLoginTD[playerid][2], "REGISTER   DELETE");
		}
		TextDrawSetString(RegisterLoginTD[playerid][1], "~b~~h~A  ~w~B  C  D  E  F  G  H  I  J  K  L  M  N  O  P  R  S~n~T  U  V  Z  Q  W  Y  X  0  1  2  3  4  5  6  7  8  9");
		for(new td = 0; td <= 2; td++) { TextDrawShowForPlayer(playerid, RegisterLoginTD[playerid][td]); }
		TextDrawShowForPlayer(playerid, RegisterLoginTD2[0]);
		TextDrawShowForPlayer(playerid, RegisterLoginTD2[1]);
		TextDrawShowForPlayer(playerid, RegisterLoginTD2[2]);
		stop LST[playerid];
	}
	mysql_free_result();
	return 1;
}

will give you rep is somebody fixes this because i really want it.

Re: MYSQL R7 error - Konstantinos - 01.05.2014

Quote:

Originally Posted by Yves

Can you show me what you mean by that?

however, the query is not a string.

Query parameter IS a string/array. I'll give a simple example so you can understand what I meant by that. It's like doing in a script:

pawn Код:

format(output[], len, const format[], {Float,_}:...);

when it's supposed you should change the arguments to whatever you want.

Also since you use R7, you should also use threaded queries. Keep in mind that using the latest version (R3

is always recommended.

Your code was a bit, so I'm not sure if you want exactly some part of code after getting whether there are rows or not.

pawn Код:

timer LoadingScreenTimer[100](playerid)
{
    format(string, sizeof(string), "%d%%~n~~w~Loading...", ++LoadingPercentage[playerid]);
    TextDrawSetString(RegisterLoginTD[playerid][5], string);
    if(LoadingPercentage[playerid] == 100)
    {
        SendClientMessage(playerid, COLOR_YELLOW, "Use keys up-down and right-left and when you select action press F!");
        format(string, sizeof(string), "Welcome %s~n~~n~Please type your password!", GetName(playerid));
        TextDrawSetString(RegisterLoginTD[playerid][0], string);
        LoadingPercentage[playerid] = 0;
        TextDrawHideForPlayer(playerid, RegisterLoginTD[playerid][5]);
        mysql_format(1, Query, "SELECT * FROM `test_table` WHERE `Name` = '%e'", GetName(playerid));
        mysql_function_query(1, Query, true, "OnPlayerDataLoad", "i", playerid);
        
        SelectedCharacter[playerid] = 0;
    }
    return 1;
}

forward OnPlayerDataLoad(playerid);
public OnPlayerDataLoad(playerid)
{
    new rows, fields;
    cache_get_data(rows, fields);
    
    if (rows)
    {
        SendClientMessage(playerid, COLOR_LIME, "You are registered, please type your password!");
        CPLK[playerid] = repeat CheckPlayerLoginKeys(playerid);
        TextDrawSetString(RegisterLoginTD[playerid][2], "LOGIN   DELETE");
    }
    else
    {
        SendClientMessage(playerid, COLOR_LIME, "You are not registered, please type your new password!");
        CPRK[playerid] = repeat CheckPlayerRegisterKeys(playerid);
        TextDrawSetString(RegisterLoginTD[playerid][2], "REGISTER   DELETE");
    }
        
    TextDrawSetString(RegisterLoginTD[playerid][1], "~b~~h~A  ~w~B  C  D  E  F  G  H  I  J  K  L  M  N  O  P  R  S~n~T  U  V  Z  Q  W  Y  X  0  1  2  3  4  5  6  7  8  9");
    for(new td = 0; td <= 2; td++) { TextDrawShowForPlayer(playerid, RegisterLoginTD[playerid][td]); }
    TextDrawShowForPlayer(playerid, RegisterLoginTD2[0]);
    TextDrawShowForPlayer(playerid, RegisterLoginTD2[1]);
    TextDrawShowForPlayer(playerid, RegisterLoginTD2[2]);
    stop LST[playerid];
}