CMD:cuff(playerid, params[]) {

    new
        string[128],
        playerName[2][MAX_PLAYER_NAME],
        target,
        Float:Pos[3];

    if(groupVariables[playerVariables[playerid][pGroup]][gGroupType] != 1) return SendClientMessage(playerid, COLOR_GREY, "You're not a law enforcement officer.");

    else if(sscanf(params, "u", target)) return SendClientMessage(playerid, COLOR_GREY, SYNTAX_MESSAGE"/cuff [playerid]");

    else if(target == playerid) return SendClientMessage(playerid, COLOR_GREY, "You can't cuff yourself.");

    else {
        if(IsPlayerInRangeOfPlayer(playerid, target, 3.0)) {
            if(playerVariables[target][pFreezeType] == 5 || playerVariables[target][pFreezeType] == 1 || (GetPlayerSpecialAction(target) == SPECIAL_ACTION_HANDSUP && playerVariables[target][pFreezeType] == 0) || playerVariables[target][pFreezeType] == 4) { // CAN NEVAR BE EXPLOITED!1 Means admin-frozen people can't be exploited out with cuffs.

                GetPlayerName(playerid, playerName[0], MAX_PLAYER_NAME);
                GetPlayerName(target, playerName[1], MAX_PLAYER_NAME);

                TogglePlayerControllable(target, 0);
                playerVariables[target][pFreezeTime] = 900;
                playerVariables[target][pFreezeType] = 2;
                GameTextForPlayer(target,"~n~~r~Handcuffed!",4000,4);

                GetPlayerPos(playerid, Pos[0], Pos[1], Pos[2]);

                format(string, sizeof(string), "* %s has handcuffed %s.", playerName[0], playerName[1]);
                nearByMessage(playerid, COLOR_PURPLE, string);
                format(string, sizeof(string),"You have handcuffed %s.", playerName[1]);
                SendClientMessage(playerid, COLOR_NICESKY, string);

                PlayerPlaySoundEx(1145, Pos[0], Pos[1], Pos[2]);
                ApplyAnimation(target, "PED", "cower", 1, 1, 0, 0, 0, 0, 1);
            }
            else SendClientMessage(playerid, COLOR_GREY, "That person must first be subdued, or have their hands up.");
        }
        else SendClientMessage(playerid, COLOR_GREY, "You're too far away.");
    }
    return 1;
}