Errors on sscanf - Printable Version

Errors on sscanf - Printable Version

+- SA-MP Forums Archive (https://sampforum.blast.hk)
+-- Forum: SA-MP Scripting and Plugins (https://sampforum.blast.hk/forumdisplay.php?fid=8)
+--- Forum: Scripting Help (https://sampforum.blast.hk/forumdisplay.php?fid=12)
+---- Forum: Help Archive (https://sampforum.blast.hk/forumdisplay.php?fid=89)
+---- Thread: Errors on sscanf (/showthread.php?tid=129342)

Errors on sscanf - Christopher. - 21.02.2010

Ok so i have got a GiveWeapon command, I've got the params of the sscanf so it has the weapon id too, This is the command:

Код:

dcmd_giveweapon(playerid, params[])
{
	new Weapon;
	new string[128];

	new WeaponPlayer[MAX_PLAYER_NAME];
	new AdministratorName[MAX_PLAYER_NAME];
	new id;

	if (PlayerInfo[playerid][Level] > 1)
	{

		if (sscanf(params, "ui", id, Weapon)) SendClientMessage(playerid, 0xFF0000AA, "Usage: /giveweapon [playerid/partname] [amount]");
		else if (id == INVALID_PLAYER_ID) SendClientMessage(playerid, 0xFF0000AA, "Player not found");
		else
		{

		  GetPlayerName(id, WeaponPlayer, sizeof(WeaponPlayer));

			GetPlayerName(playerid, AdministratorName, sizeof(AdministratorName));

			if(!strlen(Weapon)) return SendClientMessage(playerid, AdministrationError, "USAGE: /weapon [PlayerID] [WeaponID]");
			if(!IsNumeric(Weapon)) return SendClientMessage(playerid, AdministrationError, "Error: Invalid WeaponID");
			if(Weapon > 46) return SendClientMessage(playerid, AdministrationError, "Error: Weapon ID's must be 1-46");

			format(string, sizeof(string), "%s was given a weapon by Administrator %s. [Weapon: %d ]", WeaponPlayer, AdministratorName, Weapon);
			
			GivePlayerWeapon(id, Weapon, 5000);

			SendClientMessageToAll(AdministrationAnnouncement, string);

			LogCommand(string);

		}
	}
	else
	{
		SendClientMessage(playerid, AdministrationError, NotAdminError);
	}
	return 1;
}

The errors:

Код:

C:\Users\Christopher\Desktop\AdminMax.pwn(781) : error 035: argument type mismatch (argument 1)
C:\Users\Christopher\Desktop\AdminMax.pwn(782) : error 035: argument type mismatch (argument 1)
Pawn compiler 3.2.3664	 	 	Copyright © 1997-2006, ITB CompuPhase


2 Errors.

Line 781 and 782:

Код:

if(!strlen(Weapon)) return SendClientMessage(playerid, AdministrationError, "USAGE: /weapon [PlayerID] [WeaponID]");
if(!IsNumeric(Weapon)) return SendClientMessage(playerid, AdministrationError, "Error: Invalid WeaponID");

Dose anyone have any idea why that would return a error?, Thanks

Re: Errors on sscanf - aircombat - 21.02.2010

Код:

dcmd_giveweapon(playerid,params[]) {
	if(PlayerInfo[playerid][Level] >= 1) {
	  new tmp[256], tmp2[256], tmp3[256], Index; tmp = strtok(params,Index), tmp2 = strtok(params,Index), tmp3 = strtok(params,Index);
	  if(!strlen(tmp) || !strlen(tmp2)) return SendClientMessage(playerid, red, "USAGE: /giveweapon [playerid] [weapon id/weapon name] [ammo]");
		new player1 = strval(tmp), weap, ammo, WeapName[32], string[128];
		if(!strlen(tmp3) || !IsNumeric(tmp3) || strval(tmp3) <= 0 || strval(tmp3) > 99999) ammo = 500; else ammo = strval(tmp3);
		if(!IsNumeric(tmp2)) weap = GetWeaponIDFromName(tmp2); else weap = strval(tmp2);
    if(IsPlayerConnected(player1) && player1 != INVALID_PLAYER_ID) {
    	if(!IsValidWeapon(weap)) return SendClientMessage(playerid,red,"ERROR: Invalid weapon ID");
  			CMDMessageToAdmins(playerid,"GIVEWEAPON");
			GetWeaponName(weap,WeapName,32);
			format(string, sizeof(string), "You have given \"%s\" a %s (%d) with %d rounds of ammo", PlayerName2(player1), WeapName, weap, ammo); SendClientMessage(playerid,blue,string);
			if(player1 != playerid) { format(string,sizeof(string),"Administrator \"%s\" has given you a %s (%d) with %d rounds of ammo", PlayerName2(playerid), WeapName, weap, ammo); SendClientMessage(player1,blue,string); }
  			return GivePlayerWeapon(player1, weap, ammo);
	  } else return SendClientMessage(playerid,red,"ERROR: Player is not connected");
	} else return SendClientMessage(playerid,red,"ERROR: You are not a high enough level to use this command");
}

if u r using ladmin4v2 , that should work good
________
Wellbutrin side effects

Re: Errors on sscanf - Christopher. - 21.02.2010

I'm not using LAdmin its a custom admin system i am coding.

Re: Errors on sscanf - aircombat - 21.02.2010

Код:

dcmd_giveweapon(playerid,params[]) {
	if(PlayerInfo[playerid][Level] >= 1) {
	  new tmp[256], tmp2[256], tmp3[256], Index; tmp = strtok(params,Index), tmp2 = strtok(params,Index), tmp3 = strtok(params,Index);
	  if(!strlen(tmp) || !strlen(tmp2)) return SendClientMessage(playerid, red, "USAGE: /giveweapon [playerid] [weapon id/weapon name] [ammo]");
		new player1 = strval(tmp), weap, ammo, WeapName[32], string[128];
		if(!strlen(tmp3) || !IsNumeric(tmp3) || strval(tmp3) <= 0 || strval(tmp3) > 99999) ammo = 500; else ammo = strval(tmp3);
		if(!IsNumeric(tmp2)) weap = GetWeaponIDFromName(tmp2); else weap = strval(tmp2);
    if(IsPlayerConnected(player1) && player1 != INVALID_PLAYER_ID) {
    	if(!IsValidWeapon(weap)) return SendClientMessage(playerid,red,"ERROR: Invalid weapon ID");
  			GetWeaponName(weap,WeapName,32);
			format(string, sizeof(string), "You have given \"%s\" a %s (%d) with %d rounds of ammo", PlayerName2(player1), WeapName, weap, ammo); SendClientMessage(playerid,blue,string);
			if(player1 != playerid) { format(string,sizeof(string),"Administrator \"%s\" has given you a %s (%d) with %d rounds of ammo", PlayerName2(playerid), WeapName, weap, ammo); SendClientMessage(player1,blue,string); }
  			return GivePlayerWeapon(player1, weap, ammo);
	  } else return SendClientMessage(playerid,red,"ERROR: Player is not connected");
	} else return SendClientMessage(playerid,red,"ERROR: You are not a high enough level to use this command");
}

that should work
________
Grandma Live

Re: Errors on sscanf - Christopher. - 21.02.2010

Lol, I don't think you are getting the point, I just want to fix my errors not replace it with another command, And its pretty pointless using strtok with DCMD

Re: Errors on sscanf - aircombat - 21.02.2010

just one more thing , the command u posted , when i put it in my gamemode , i get no errors , it works properly here is what i use to define sscanf if that's the problem :

Код:

//------------------[SSCANF]-------------------------------------
stock sscanf(string[], format[], {Float,_}:...)
{
	#if defined isnull
		if (isnull(string))
	#else
		if (string[0] == 0 || (string[0] == 1 && string[1] == 0))
	#endif
		{
			return format[0];
		}
	#pragma tabsize 4
	new
		formatPos = 0,
		stringPos = 0,
		paramPos = 2,
		paramCount = numargs(),
		delim = ' ';
	while (string[stringPos] && string[stringPos] <= ' ')
	{
		stringPos++;
	}
	while (paramPos < paramCount && string[stringPos])
	{
		switch (format[formatPos++])
		{
			case '\0':
			{
				return 0;
			}
			case 'i', 'd':
			{
				new
					neg = 1,
					num = 0,
					ch = string[stringPos];
				if (ch == '-')
				{
					neg = -1;
					ch = string[++stringPos];
				}
				do
				{
					stringPos++;
					if ('0' <= ch <= '9')
					{
						num = (num * 10) + (ch - '0');
					}
					else
					{
						return -1;
					}
				}
				while ((ch = string[stringPos]) > ' ' && ch != delim);
				setarg(paramPos, 0, num * neg);
			}
			case 'h', 'x':
			{
				new
					num = 0,
					ch = string[stringPos];
				do
				{
					stringPos++;
					switch (ch)
					{
						case 'x', 'X':
						{
							num = 0;
							continue;
						}
						case '0' .. '9':
						{
							num = (num << 4) | (ch - '0');
						}
						case 'a' .. 'f':
						{
							num = (num << 4) | (ch - ('a' - 10));
						}
						case 'A' .. 'F':
						{
							num = (num << 4) | (ch - ('A' - 10));
						}
						default:
						{
							return -1;
						}
					}
				}
				while ((ch = string[stringPos]) > ' ' && ch != delim);
				setarg(paramPos, 0, num);
			}
			case 'c':
			{
				setarg(paramPos, 0, string[stringPos++]);
			}
			case 'f':
			{

				new changestr[16], changepos = 0, strpos = stringPos;
				while(changepos < 16 && string[strpos] && string[strpos] != delim)
				{
					changestr[changepos++] = string[strpos++];
  				}
				changestr[changepos] = '\0';
				setarg(paramPos,0,_:floatstr(changestr));
			}
			case 'p':
			{
				delim = format[formatPos++];
				continue;
			}
			case '\'':
			{
				new
					end = formatPos - 1,
					ch;
				while ((ch = format[++end]) && ch != '\'') {}
				if (!ch)
				{
					return -1;
				}
				format[end] = '\0';
				if ((ch = strfind(string, format[formatPos], false, stringPos)) == -1)
				{
					if (format[end + 1])
					{
						return -1;
					}
					return 0;
				}
				format[end] = '\'';
				stringPos = ch + (end - formatPos);
				formatPos = end + 1;
			}
			case 'u':
			{
				new
					end = stringPos - 1,
					id = 0,
					bool:num = true,
					ch;
				while ((ch = string[++end]) && ch != delim)
				{
					if (num)
					{
						if ('0' <= ch <= '9')
						{
							id = (id * 10) + (ch - '0');
						}
						else
						{
							num = false;
						}
					}
				}
				if (num && IsPlayerConnected(id))
				{
					setarg(paramPos, 0, id);
				}
				else
				{
					#if !defined foreach
						#define foreach(%1,%2) for (new %2 = 0; %2 < MAX_PLAYERS; %2++) if (IsPlayerConnected(%2))
						#define __SSCANF_FOREACH__
					#endif
					string[end] = '\0';
					num = false;
					new
						name[MAX_PLAYER_NAME];
					id = end - stringPos;
					foreach (Player, playerid)
					{
						GetPlayerName(playerid, name, sizeof (name));
						if (!strcmp(name, string[stringPos], true, id))
						{
							setarg(paramPos, 0, playerid);
							num = true;
							break;
						}
					}
					if (!num)
					{
						setarg(paramPos, 0, INVALID_PLAYER_ID);
					}
					string[end] = ch;
					#if defined __SSCANF_FOREACH__
						#undef foreach
						#undef __SSCANF_FOREACH__
					#endif
				}
				stringPos = end;
			}
			case 's', 'z':
			{
				new
					i = 0,
					ch;
				if (format[formatPos])
				{
					while ((ch = string[stringPos++]) && ch != delim)
					{
						setarg(paramPos, i++, ch);
					}
					if (!i)
					{
						return -1;
					}
				}
				else
				{
					while ((ch = string[stringPos++]))
					{
						setarg(paramPos, i++, ch);
					}
				}
				stringPos--;
				setarg(paramPos, i, '\0');
			}
			default:
			{
				continue;
			}
		}
		while (string[stringPos] && string[stringPos] != delim && string[stringPos] > ' ')
		{
			stringPos++;
		}
		while (string[stringPos] && (string[stringPos] == delim || string[stringPos] <= ' '))
		{
			stringPos++;
		}
		paramPos++;
	}
	do
	{
		if ((delim = format[formatPos++]) > ' ')
		{
			if (delim == '\'')
			{
				while ((delim = format[formatPos++]) && delim != '\'') {}
			}
			else if (delim != 'z')
			{
				return delim;
			}
		}
	}
	while (delim > ' ');
	return 0;
}

________
Vapor Genie Vaporizer Reviews

Re: Errors on sscanf - Christopher. - 23.02.2010

Still no fix for it :/

Re: Errors on sscanf - dice7 - 23.02.2010

what are the lines 781 and 782

nvm, found it

pawn Код:

if(!strlen(Weapon)) return SendClientMessage(playerid, AdministrationError, "USAGE: /weapon [PlayerID] [WeaponID]");
if(!IsNumeric(Weapon)) return SendClientMessage(playerid, AdministrationError, "Error: Invalid WeaponID");

strlen and IsNumeric are functions for strings and Weapon is an integer

You don't need this

pawn Код:

if(!strlen(Weapon)) return SendClientMessage(playerid, AdministrationError, "USAGE: /weapon [PlayerID] [WeaponID]");

sscanf has its inbuilt error check to see if the string typed by the player can be deformated to fit the variables added as the third argument

pawn Код:

if(!IsNumeric(Weapon)) return SendClientMessage(playerid, AdministrationError, "Error: Invalid WeaponID");

Should be

pawn Код:

if(Weapon < 0 || Weapon > 46)return SendClientMessage(playerid, AdministrationError, "Error: Invalid WeaponID");

because valid weapon ids are between 0 and 46
https://sampwiki.blast.hk/wiki/Weapons

Re: Errors on sscanf - Miguel - 23.02.2010

Try this:

pawn Код:

dcmd_giveweapon(playerid, params[])
{
    if(PlayerInfo[playerid][Level] < 1) return SendClientMessage(playerid, AdministrationError, NotAdminError);

    new
      id,
      weapon,
      name[2][24],
      string[110];

    if(sscanf(params, "ud", id, weapon)) return SendClientMessage(playerid, 0xFF0000AA, "Usage: /giveweapon [playerid/partname] [amount]");
    else if(!IsPlayerConnected(playerid)) return SendClientMessage(playerid, 0xFF0000AA, "Player not found");
    else if(0 > weapon > 46) return SendClientMessage(playerid, AdministrationError, "Error: Weapon ID's must be 1-46");
    else
    {
        GivePlayerWeapon(id, weapon, 5000);
        GetPlayerName(playerid, name[0], 24);
        GetPlayerName(id, name[1], 24);
        format(string, sizeof(string), "%s was given a weapon by Administrator %s. [Weapon: %d]", name[1], name[0], weapon);
        SendClientMessageToAll(AdministrationAnnouncement, string);
        LogCommand(string);
    }
    return 1;
}

Re: Errors on sscanf - Christopher. - 23.02.2010

Quote:

Originally Posted by dice7

what are the lines 781 and 782

nvm, found it

pawn Код:

if(!strlen(Weapon)) return SendClientMessage(playerid, AdministrationError, "USAGE: /weapon [PlayerID] [WeaponID]");
if(!IsNumeric(Weapon)) return SendClientMessage(playerid, AdministrationError, "Error: Invalid WeaponID");

strlen and IsNumeric are functions for strings and Weapon is an integer

You don't need this

pawn Код:

if(!strlen(Weapon)) return SendClientMessage(playerid, AdministrationError, "USAGE: /weapon [PlayerID] [WeaponID]");

sscanf has its inbuilt error check to see if the string typed by the player can be deformated to fit the variables added as the third argument

pawn Код:

if(!IsNumeric(Weapon)) return SendClientMessage(playerid, AdministrationError, "Error: Invalid WeaponID");

Should be

pawn Код:

if(Weapon < 0 || Weapon > 46)return SendClientMessage(playerid, AdministrationError, "Error: Invalid WeaponID");

because valid weapon ids are between 0 and 46
https://sampwiki.blast.hk/wiki/Weapons

Thanks man done the trick.

Thanks, Chris.